如何在 VBScript 中测试布尔表达式？

Question

我正在尝试将代码从 https://stackoverflow.com/questions/4554014/how-to-examine-and-manipulate-iis-metadata-in-c 转换为 VBVcript。

我的问题在于这段代码：

Function LocateVirtualDirectory(ByVal siteName, ByVal vdirName)
    On Error Resume Next
    Dim site
    For Each site in w3svc
        If (site.KeyType = "IIsWebServer") And (site.ServerComment = siteName) Then
            Set LocateVirtualDirectory = GetObject(site.Path & "/ROOT/" & vdirName)
            Exit Function
        End If
    Next
End Function

如果site.ServerComment 是Empty，则整个布尔表达式接收值Empty，它不是 False，因此输入 then 语句。

编写该表达式的正确方法是什么？越短越好。

谢谢。

Answer 1

我会简单地嵌套If 语句，并插入一个额外的检查来防止ServerComment 是Empty 的情况。我还将site.ServerComment 的值提取到临时变量comment 中，这样您就不会访问该属性两次。

例如：

Function LocateVirtualDirectory(ByVal siteName, ByVal vdirName)
    On Error Resume Next
    Dim site
    Dim comment
    For Each site in w3svc
        If site.KeyType = "IIsWebServer" Then
            comment = site.ServerComment
            If (comment <> Empty) And (comment = siteName) Then
                Set LocateVirtualDirectory = GetObject(site.Path & "/ROOT/" & vdirName)
                Exit Function
            End If
        End If
    Next
End Function

嵌套If 语句的另一个好处是使评估短路。 VBScript（和 VB 6）不会短路条件求值——And 运算符作为一个逻辑运算符工作，要求条件的两边都经过测试才能确定结果。因为如果KeyType 不匹配，则没有理由检查ServerComment，因此通过短路表达式可以获得一点性能。在 VBScript 中实现这一点的唯一方法是嵌套（没有 AndAlso）。

我还应该指出，如果值= True，测试绝对没有意义。您可以简单地将(site.ServerComment = siteName) = True 重写为site.ServerComment = siteName，并获得完全相同的结果。我至少花了几分钟才弄清楚你的原始代码做了什么，因为那是一种不自然的编写条件的方式。