压缩bash中数字范围的范围

Question

我有一个名为“ranges.csv”的 csv 文件，其中包含：

start_range,stop_range  
9702220000,9702220999  
9702222000,9702222999  
9702223000,9702223999  
9750000000,9750000999  
9750001000,9750001999  
9750002000,9750002999  

我正在尝试组合 stop_range=start_range-1 的范围，并将结果输出到另一个名为“ranges2.csv”的 csv 文件中。所以输出将是：

9702220000,9702220999  
9702222000,9702223999  
9750000000,9750002999  

此外，我需要知道有多少范围包含一个压缩范围（例如：对于新范围9750000000,9750002999，我需要知道在压缩之前有 3 个范围）。此信息将帮助我创建一个名为“ranges3.csv”的新 csv 文件，该文件应仅包含其中范围最多的范围（最全面的区域）：

    9750000000,9750002999  

我在想这样的事情：

if (stop_range = start_range-1)  
  new_stop_range = start_range-1  

但我不是很聪明，而且我是 bash 脚本的新手。
我知道如何在另一个文件中输出结果，但我需要的功能让我头疼。

Answer 1

我认为这可以解决问题：

#!/bin/bash

awk '
  BEGIN { FS = OFS = ","}
  NR == 2 {
    start = $1; stop = $2; i = 1
  }
  NR > 2 {
    if ($1 == (stop + 1)) {
      i++; 
      stop = $2
    } else {
      if (++i > max) {
        maxr = start "," stop;
        max = i
      }  
      start = $1
      i = 0
    }
    stop = $2
  }
  END { 
    if (++i > max) {
      maxr =  start "," stop;
    }
    print maxr
  }
' ranges.csv

Answer 2

假设您的范围已排序，那么此代码只为您提供合并的范围：

awk 'BEGIN{FS=OFS=","}
     (FNR>1) && ($1!=e+1){print b,e; b=e="" }
     ($1==e+1){ e=$2; next }
     { b=$1; e=$2 }
     END { print b,e }' file    

下面你会得到相同的结果，但范围计数：

awk 'BEGIN{FS=OFS=","}
     (FNR>1) && ($1!=e+1){print b,e,c; b=e=c="" }
     ($1==e+1){ e=$2; c++; next }
     { b=$1; e=$2; c=1 }
     END { print b,e,c }' file

如果你想要最大的，你可以在第三列排序。我不想制定规则来给出计数最多的范围，因为可能有多个。

如果你真的只想要最大合并的所有范围：

awk 'BEGIN{FS=OFS=","}
     (FNR>1) && ($1!=e+1){ 
        a[c] = a[c] (a[c]?ORS:"") b OFS e
        m=(c>m?c:m)
        b=e=c=""
     }
     ($1==e+1){ e=$2; c++; next }
     { b=$1; e=$2; c=1 }
     END { a[c] = a[c] (a[c]?ORS:"") b OFS e
           m=(c>m?c:m)
           print a[m]
     }' file