使用多个 vlookup 的条件格式答案

【问题标题】：Conditional Formatting using multiple vlookups使用多个 vlookup 的条件格式
【发布时间】：2018-06-21 14:00:32
【问题描述】：

我有一个 Excel 电子表格，我正在尝试根据多个条件进行条件格式设置。我必须突出显示（A 列值与 C 列匹配）和（B 列与 D 列匹配）的行。我尝试了 3 种方法，但都没有给我预期的结果- 方法 1 - 我尝试使用这两条规则进行条件格式化 - (VLOOKUP($A2,C2:C93,1,FALSE))>0 (VLOOKUP($B2,D2:D93,1,FALSE))>0 并将其应用于 $A$2:$D$5745 但这没有按预期工作。

方法 2- 我尝试使用 if 但这也没有提供我想要的结果 =if(VLOOKUP(A2,$C2:$C93,1,FALSE)>0 & VLOOKUP(B2,$D2:$D93,1,FALSE),True,False)>0 将其应用于 $A$2:$D$5745

方法3- =AND((VLOOKUP($A2,C2:C93,1,FALSE))>0,(VLOOKUP($B2,D2:D93,1,FALSE))>0) 将其应用于 $A$2:$D$5745

重新表述这个问题 - 我想突出显示 Col A 中的 CustEID 和 B 列中的 Account EID 与 col C 中的 CustEID 和 col D 中的 Account EID 匹配的所有行。

有人可以指导我吗？

【问题讨论】：

不要使用&。使用AND 函数来组合您的两个VLOOKUP 语句。看起来应该是=if(AND(VLOOKUP(A2,$C2:$C93,1,FALSE)>0,VLOOKUP(B2,$D2:$D93,1,FALSE)),True,False)>0
谢谢..有一个错字- =if(AND(VLOOKUP(A2,$C2:$C93,1,FALSE)>0,VLOOKUP(B2,$D2:$D93,1, FALSE)>0),True,False)>0
不幸的是，这也没有按预期工作。似乎它仅在（单元格 A 中的值 = C 中的值）和（B 中的值 = D 中的值）时突出显示。它没有进行垂直查找。
如果单元格 A2 中的值出现在 C 列的任何位置，而 B2 的值出现在 D 列的任何位置，您想突出显示第 2 行吗？
是的。这正是我想要做的。 A2 出现在 C 列的任何位置，而 B2 的值出现在 D 列的任何位置。但如上面的打印屏幕所示 - 这里的问题是 B 列中的一些值是 Null。我试图在 C 列的任何位置找到 A2（CustEID），然后在 D 列的任何位置查找 B2（AccountEID）。帐户 EID 可能为 NULL。

标签： excel vlookup conditional-formatting

【解决方案1】：

这是我能够开始工作的。

VLOOKUP 计算返回“找到”值或#N/A。通过使用逻辑检查 >0 修改公式，这会将结果转换为布尔值 (TRUE)，但仅在 VLOOKUP 返回有效值的情况下。在您的许多情况下，您的公式的计算结果仍为 #N/A。

因此：=VLOOKUP(A2,$C$2:$C$93,1,FALSE)>0 将返回 TRUE 或 #N/A。

我已将公式修改为=IFNA(VLOOKUP(A2,$C$2:$C$93,1,FALSE)>0,FALSE)，这会强制整个公式返回真正的布尔值TRUE 或FALSE。

公式中的单元格范围引用需要锁定在特定范围内，在条件格式公式的上下文中，这些范围不会被评估为“相对”。所以你的公式VLOOKUP($A2,C2:C93,1,FALSE) 使用范围C2:C93 也将“滑动”（我自己的这个公式的术语是“相对的”），因为它沿着行前进。因此，您的每个公式都需要使用 VLOOKUP($A2,$C$2:$C$93,1,FALSE) 锁定它。

请注意，公式中唯一保持相对关系的部分是行号——在本例中为 2。因此，您将在第 2 行开始设置条件格式。

结合这些公式来完成您想要应用的完整测试可以得到您

=AND(IFNA(VLOOKUP($A2,$C$2:$C$93,1,FALSE)>0,FALSE),IFNA(VLOOKUP($B2,$D$2:$D$93,1,FALSE)>0,FALSE))

将此作为整行应用于您的条件格式需要最后一次调整。您必须删除列引用，而不是将您的规则应用于范围 $A$2:$D$5745。所以应用范围变成了$2:$5745。

这就是我将所有内容放在一起后得到的结果：

【讨论】：