如何运行带有变量的命令？ /// 如何生成带有变量的随机数？

Question

我知道 set zeroThroughNine=%Random%*9/32768 后跟 echo %zeroThroughNine% 将产生一个介于 0 和 9 之间的随机数。但似乎解释器不会在每次调用变量时评估它的内容，并且作为例如，echo %zeroThroughNine% 每次都会产生 7 个。

我查找了一种使用变量运行命令的方法，以便我可以尝试强制它工作。我喜欢这个问题，因为它的方法非常基础。类似于“如何使用变量运行命令？”的内容，适当地标记。我不太关心答案，因为它非常狭窄。投票和选择的最高答案是：

简单。只需运行set commandVar=echo "Hello world."，然后运行echo %commandVar%。

当然，事实是这只适用于 echo 命令。 >：[

无论如何，我会停止抱怨。这是我尝试过的：

set zeroThroughNine=set /a number=%Random%*9/32768 & echo %number% 后跟echo %zeroThroughNine%

不幸的是，我的 SET 命令的 & echo %number% 部分立即运行，产生“%number%”作为输出——例如，使用echo %zeroThroughNine% 产生“set /a number=8436*9/32768”作为输出。

所以有两个问题：如何使用变量（或一些替代方法）普遍实现运行命令，也许更紧迫的是，如何在每个新命令调用时在命令行产生一个新的随机数？

Answer 1

您应该在将 zeroThroughNine 设置为命令之前设置 number，如下所示：

set /a number=%Random%*9/32768
set zeroThroughNine=echo %number%
%zeroThroughNine%

另外，由于 zeroThroughNine 已经是一个 echo 命令，你不需要在它之前添加额外的 echo。

编辑：

考虑到你的 Random 计算是不必要的复杂，最终的代码应该是这样的（1 - 10 除外）：

set /a number=%Random% %% 10
set zeroThroughNine=echo %number%
%zeroThroughNine%

重要的是，与其试图在一行中完成所有操作，不如将其分成两行来提高可读性。

Answer 2

The CALL SET syntax 允许评估 variable substring，CALL page 对此技术有更多详细信息，在大多数情况下，更好的方法是使用 Setlocal EnableDelayedExpansion。

命令行（请注意，所有% 百分号都是escaped 为^%，并且> 和& 字符在一对" 双引号内转义：

set "zeroThroughNine=call set /a number=^%Random^% ^% 10>nul & call echo number=^%number^%"
%zeroThroughNine%
for /L %G in (1, 1, 10) do @%zeroThroughNine%

批处理脚本，CALL 方法（注意所有% 百分号都转义为%%）：

@echo OFF
SETLOCAL
set "_zeroThroughNine=call set /a _number=%%Random%% %%%% 10 & call echo number=%%_number%%"
echo check variables 
set _
echo output
%_zeroThroughNine%
for /L %%G in (1,1,10) do %_zeroThroughNine%
echo check variables after evaluating 
set _
ENDLOCAL

批处理脚本，EnableDelayedExpansion 仅用于输出：

@echo OFF
SETLOCAL EnableExtensions DisableDelayedExpansion
set "_zeroThroughNine=set /a _number=!Random! %% 10 & echo Number=!_number!"

SETLOCAL EnableDelayedExpansion
echo check variables 
set _
echo output
%_zeroThroughNine%
for /L %%G in (1,1,10) do %_zeroThroughNine%
echo check variables after evaluating 
set _
ENDLOCAL
ENDLOCAL

批处理脚本，EnableDelayedExpansion脚本范围（注意!感叹号转义为^!）：

@echo OFF
SETLOCAL EnableExtensions EnableDelayedExpansion
set "_zeroThroughNine=set /a _number=^!Random^! %% 10 & echo NUMBER=^!_number^!"
echo check variables 
set _
echo output
%_zeroThroughNine%
for /L %%G in (1,1,10) do %_zeroThroughNine%
echo check variables after evaluating 
set _
ENDLOCAL

Answer 3

查看this question。基本上，这是 %random% 环境变量如何工作的问题......

编辑：

详细地说，您的随机值始终为 7 的原因是因为 cmd 的伪随机数生成器是如何工作的，而不是因为变量的解释方式。 this answer 很好地解释了这个问题。

基本上，在批处理文件的重复运行中，%RANDOM% 将产生一个非常接近前一次运行的值。因此，表达式%RANDOM%*9/32768 在每次单独运行中都会产生相同的结果，因为它是随机值。

如果我理解正确，您要问的问题是如何更好地生成随机值 0 - 9（含），这将通过使用以下表达式：

set /a zeroThroughNine=%RANDOM% %% 10