如何使用批处理将工作目录转换为 8.3 短文件名？ [复制]

Question

我正在编写一个构建脚本，如果用户构建脚本的目录包含空格，那么一切都会崩溃。为了解决这个问题，我想到了使用 8.3 文件名，以便 drive:\Documents and setttings\whatever 变为 drive:\Docume~1\whatever 。当前目录可以通过查询环境变量%CD%找到。

如何将 %CD% 转换为短文件路径？

Answer 1

for %f in ("%cd%") do @echo %~sf

编辑：如果您在批处理文件中使用它，请不要忘记使用 %%。 像这样

for %%f in ("%cd%") do @echo %%~sf

在我的机器上：

C:\Users\preet>cd "\Program Files"
C:\Program Files>for %f in ("%cd%") do @echo %~sf
C:\PROGRA~1

其他选项：

此外，FOR 变量引用的替换已得到增强。 您现在可以使用以下可选语法：

    %~I         - expands %I removing any surrounding quotes (")
    %~fI        - expands %I to a fully qualified path name
    %~dI        - expands %I to a drive letter only
    %~pI        - expands %I to a path only
    %~nI        - expands %I to a file name only
    %~xI        - expands %I to a file extension only
    %~sI        - expanded path contains short names only
    %~aI        - expands %I to file attributes of file
    %~tI        - expands %I to date/time of file
    %~zI        - expands %I to size of file
    %~$PATH:I   - searches the directories listed in the PATH
                   environment variable and expands %I to the
                   fully qualified name of the first one found.
                   If the environment variable name is not
                   defined or the file is not found by the
                   search, then this modifier expands to the
                   empty string

The modifiers can be combined to get compound results:

    %~dpI       - expands %I to a drive letter and path only
    %~nxI       - expands %I to a file name and extension only
    %~fsI       - expands %I to a full path name with short names only
    %~dp$PATH:I - searches the directories listed in the PATH
                   environment variable for %I and expands to the
                   drive letter and path of the first one found.
    %~ftzaI     - expands %I to a DIR like output line

Answer 2

更好：在所有路径周围使用引号字符 (")。