Excel VBA时间戳未更新

Question

我正在构建一个工作表，它将跟踪我们传入的预告片并将该信息放在仪表板上。我有 VBA 设置，当用户将 A 列中的单元格从此处更改为已关闭时，它会将该行复制到下一张将保留预告片历史记录的工作表。

我的问题是完成页面上的 VBA 时间戳在复制该行时没有更新。我知道 vba 可以工作，因为我可以更改已完成工作表上的预告片编号，它将触发 vba 并出现时间戳。但是当从仪表板表复制该行时，我需要显示该时间戳。

我是否遗漏了一些我需要打开以帮助触发时间戳的东西？

谢谢

编辑-对不起，我没有添加代码。这是我在已完成工作表上的时间戳

Private Sub Worksheet_Change(ByVal Target As Range)

If Intersect(Target, Range("C2:C10000")) Is Nothing Then Exit Sub
If Target.Count > 1 Then Exit Sub
If Target = "" Then Exit Sub

With Application
    .ScreenUpdating = False
    .EnableEvents = False
    With Cells(Target.Row, 10)
        .Value = Now
        .NumberFormat = "mm/dd/yyyy hh:mm:ss"
    End With
    .EnableEvents = True
    .ScreenUpdating = True
End With

End Sub

我的仪表板页面的代码将复制该行

Private Sub Worksheet_Change(ByVal Target As Range)

If Intersect(Target, Range("A2:A5000")) Is Nothing Then Exit Sub
If Target.Count > 1 Then Exit Sub
If Target = "" Then Exit Sub

Dim NR As Long

With Application
    .EnableEvents = False
    .ScreenUpdating = False
    Select Case Target.Value
        Case "Closed"
          Range("A" & Target.Row & ":z" & Target.Row).Copy _
          Worksheets("Completed").Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
          Target.EntireRow.Delete Shift:=xlUp
    End Select
    .EnableEvents = True
    .ScreenUpdating = True
End With

End Sub

Answer 1

这是我想出的解决方案。我不明白为什么需要两个工作表功能就足够了。将此代码放在仪表板工作表中，它将复制并粘贴到已完成的工作表中。我在代码中添加了一些内容。首先，错误处理，如果出现错误并且.EnableEvents = False 是执行的最后一行之一，则后续事件不会触发，您不会对自己满意。我还添加了一些End If，您的代码中似乎缺少这些。我在代码中添加了一些 cmets，以便您了解我在哪里进行了更改。

Private Sub Worksheet_Change(ByVal Target As Range)
  On Error GoTo ErrorHandler

If Intersect(Target, Range("A2:A5000")) Is Nothing _
   Then Exit Sub
If Target.Count > 1 Then
   Exit Sub
End If

If Target = "" Then
   Exit Sub
End If

Dim NR As Long
With Application
  .EnableEvents = False
  .ScreenUpdating = False
  Select Case Target.Value
    Case "Closed"
      Range("A" & Target.Row & ":z" & Target.Row).Copy _
      Worksheets("Completed").Range("A" & Rows.Count).End(xlUp).Offset(1, 0)
      'get the last cell used.
      Set lastCell = Worksheets("Completed").Range("A" & Rows.Count).End(xlUp)
      'new line of code
      lastCell.Offset(0, 10).Value = Now
      lastCell.Offset(0, 10).NumberFormat = "mm/dd/yyyy hh:mm:ss"
      Target.EntireRow.Delete Shift:=xlUp
   End Select
  .EnableEvents = True
  .ScreenUpdating = True

End With

Exit Sub
ErrorHandler:
    Application.EnableEvents = True
    Application.ScreenUpdating = True
    MsgBox "You have encountered an error. Please notify admin"
End Sub