XSLT 将特定节点下的 xml 块转换为该节点的 xml 转义内容

Question

任何关于如何解决以下问题的想法都将受到高度赞赏。

输入：

<p>
    <div>
     Original<br/>This is the original <b>acid</b>, a hydroxy monocarboxylic <span class="hl1">acid</span>.
    </div>
</p>

期望的输出：

<p>
    <div>
     Original&lt;br/&gt;This is the original &lt;b&gt;acid&lt;/b&gt;, a hydroxy monocarboxylic &lt;span class=&quot;hl1&quot;&gt;acid&lt;/span&gt;.
    </div>
</p>

尝试 1：

`<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output omit-xml-declaration="yes" indent="no" encoding="UTF-8"/>
<!--The identity template -->
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="div">
    <xsl:copy>
            <xsl:value-of select="/" disable-output-escaping="no"/>
    </xsl:copy>
</xsl:template>

`

尝试2： 作为替代方案，我考虑将子元素的内容放入 CDATA 包装器中。

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
<xsl:output omit-xml-declaration="yes" indent="no" encoding="UTF-8"/>
<!--The identity template -->
<xsl:template match="node()|@*">
    <xsl:copy>
        <xsl:apply-templates select="node()|@*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="div">
    <xsl:copy>
            <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
            <xsl:value-of select="/" />
            <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
    </xsl:copy>
</xsl:template>

但这并没有给我我想要的。 有人有更好的主意吗？我正在使用 XSLT 2.0

Answer 1

这是一个使用 XSLT 3.0 serialize() 的建议，由 Saxon 9.6 HE、PE 和 EE 支持：

<xsl:stylesheet version="3.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="div">
  <xsl:copy>
    <xsl:apply-templates mode="serialize"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="node()" mode="serialize">
  <xsl:variable name="ser-params">
    <output:serialization-parameters xmlns:output="http://www.w3.org/2010/xslt-xquery-serialization">
      <output:omit-xml-declaration value="yes"/>
    </output:serialization-parameters>
  </xsl:variable>
  <xsl:value-of select="serialize(., $ser-params/*)"/>
</xsl:template>

</xsl:stylesheet>

对于旧版本的 Saxon 9，您可以使用扩展功能序列化，如 http://xsltransform.net/pPqsHTx 所示：

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  exclude-result-prefixes="xs">

<xsl:output name="inline" omit-xml-declaration="yes"/>

<xsl:template match="@* | node()">
  <xsl:copy>
    <xsl:apply-templates select="@* | node()"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="div">
  <xsl:copy>
    <xsl:apply-templates mode="serialize"/>
  </xsl:copy>
</xsl:template>

<xsl:template match="node()" mode="serialize">

  <xsl:value-of xmlns:saxon="http://saxon.sf.net/" select="saxon:serialize(., 'inline')"/>
</xsl:template>

</xsl:stylesheet>

Answer 2

如果您将xsl:value-of 更改为xsl:copy-of 并调整select，您的第二次尝试应该会起作用：

<xsl:template match="div">
    <xsl:copy>
        <xsl:text disable-output-escaping="yes">&lt;![CDATA[</xsl:text>
        <xsl:copy-of select="node()" />
        <xsl:text disable-output-escaping="yes">]]&gt;</xsl:text>
    </xsl:copy>
</xsl:template>