信号处理程序不适用于双重评估

Question

我有这段代码可以让一个长时间运行的进程超时（在这种情况下为sleep）：

#!/usr/bin/env perl
use strict;
use warnings;

die "Usage: $0 SLEEP TIMEOUT\n" unless @ARGV == 2;
my ( $sleep, $timeout ) = @ARGV;

$|++;

eval {
    local $SIG{ALRM} = sub { die "TIMEOUT\n" };
    alarm $timeout;

    eval {
        # long-running process
        print "Going to sleep ... ";
        sleep $sleep;
        print "DONE\n";
    };  

    alarm 0;    # cancel timeout
};  

die $@ if $@;

当我以./alarm 5 2 运行它时，我希望它会die 说“超时”。但是它以 0 退出并且什么也没说。当我删除内部eval 块（不是块的内容，只是eval）时，它按预期工作。有人可以解释这是为什么吗？谢谢。

Answer 1

因为您在第一个eval 块中捕获错误，而第二个eval 块没有异常并清除$@。

eval {
    local $SIG{ALRM} = sub { die "TIMEOUT\n" };
    alarm $timeout;

    eval {
        # long-running process
        print "Going to sleep ... ";
A:      sleep $sleep;
        print "DONE\n";
    };  
B:

    alarm 0;    # cancel timeout
C:};  

die $@ if $@;

$sleep > $timeout，所以在A:，你的程序会抛出一个SIGALRM。该信号被您的本地信号处理程序捕获并调用die "TIMEOUT\n"。因此 Perl 将 $@ 设置为 "TIMEOUT\n" 并在 B: 处恢复执行。然后，您的程序会到达C:，而不会出现任何其他错误。由于您的外部eval 块正常完成，Perl 清除$@，并且您的最终die 语句不会执行。

要做你想做的事，你也可以

1. 不要在外层使用eval
2. 在外部块的末尾添加另一个 die $@ if $@ 调用