创建 PDF 编译错误“应用程序：定义或对象定义错误”

Question

我有一个 VBA 用户表单，用户可以在其中搜索数据库表中的某些术语。它在单独的表格中生成结果，当用户单击打印按钮时，它会创建一个 PDF，其中包含搜索结果表格中的所有数据。

编译错误

“应用程序：定义的或对象定义的错误”

Sub CreatePDF()

    Sheet4.Select
    Range("A1:N25").Select
 

        ThisWorkbook.Sheets("SearchData").Select
        Selection.ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            Orientation:=xlLandscape, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
               
       
    Sheet4.Select
    Range("A1").Select

End Sub

突出显示的行是：

Selection.ExportAsFixedFormat _ Type:=xlTypePDF, _             
  Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _             
  Quality:=xlQualityStandard, _
  Orientation:=xlLandscape, _
  IncludeDocProperties:=True, _
  IgnorePrintAreas:=False, _
  OpenAfterPublish:=True

Answer 1

方向

PageSetup.Orientation

Range.Orientation

Worksheet.ExportAsFixedFormat method 中没有 Orientation 参数。
你可以试试这个：

Option Explicit

Sub CreatePDF()

    With ThisWorkbook.Worksheets("SearchData")
        .PageSetup.Orientation = xlLandscape
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
    End With
    
    With Sheet4
        .Activate
        .Range("A1").Select
    End With

End Sub

或者如果你想打印范围：

Sub CreatePDF2()
 
    With Sheet4.Range("A1:N25")
        .Worksheet.PageSetup.Orientation = xlLandscape
        .Orientation = xlHorizontal
        .ExportAsFixedFormat _
            Type:=xlTypePDF, _
            Filename:="D:\AliBinAli\Security Visitor App\temp.pdf", _
            Quality:=xlQualityStandard, _
            IncludeDocProperties:=True, _
            IgnorePrintAreas:=False, _
            OpenAfterPublish:=True
        .Worksheet.Activate
        .Cells(1).Select   
    End With

End Sub