安装过程中如何显示本地化的程序文件名（显示名）？

Question

我目前正在创建一个安装程序，它的默认安装目录为 Program Files。为此，我使用了{pf}。

这是一个德语程序，仅在德国使用，虽然安装程序在选择目标目录期间完全使用德语，但安装程序仍显示 C:\Program Files 而不是本地化名称 C:\Programme。

是否可以改为显示C:\Programme？功能上一切正常，应用程序安装在C:\Programme。我只是担心基本用户可能会因为阅读 C:\Program Files 而感到困惑。

编辑：更多信息：我知道C:\Programme 或Program Files 的任何其他本地化名称只是一个显示名称，物理路径始终是Program Files。哪个 Windows 版本或 Windows 有什么语言都没有关系。但是我仍然希望设置在安装过程中显示C:\Programme。

我的测试机器在 Windows 7 和 Windows 10 上。

Answer 1

Inno Setup 不支持。

你必须伪造它。您可以根据需要将DirEdit 的内容动态转换为显示名称/从显示名称转换：

• 在“选择目标位置”页面激活时转换为显示名称
• 点击“浏览”按钮时转换为物理路径。
• 在选择新路径时转换为显示名称。
• 点击“下一步”按钮时转换为物理路径。

function ToDisplayName(Path: string): string;
begin
  Result := ???;
end;

function FromDisplayName(Path: string): string;
begin
  Result := ???;
end;

var
  DirBrowseButtonClickOrig: TNotifyEvent;
  OnSelectDir: Boolean;

procedure DirBrowseButtonClick(Sender: TObject);
begin
  WizardForm.DirEdit.Text := FromDisplayName(WizardForm.DirEdit.Text);
  DirBrowseButtonClickOrig(Sender);
  WizardForm.DirEdit.Text := ToDisplayName(WizardForm.DirEdit.Text);
end;

procedure InitializeWizard();
begin
  DirBrowseButtonClickOrig := WizardForm.DirBrowseButton.OnClick;
  WizardForm.DirBrowseButton.OnClick := @DirBrowseButtonClick;
  OnSelectDir := False;
end;

procedure CurPageChanged(CurPageID: Integer);
begin
  if CurPageID = wpSelectDir then
  begin
    OnSelectDir := True;
    WizardForm.DirEdit.Text := ToDisplayName(WizardForm.DirEdit.Text);
  end
    else
  begin
    if OnSelectDir then
    begin
      OnSelectDir := False;
      WizardForm.DirEdit.Text := FromDisplayName(WizardForm.DirEdit.Text);
    end;
  end;
end;

一个棘手的部分当然是ToDisplayName 和FromDisplayName 函数的实现。

真正的本机实现将非常复杂，如果您可以使用 Pascal 脚本的有限功能（尤其是缺少指针）来实现它，甚至是值得怀疑的。

但是对于您的特定需求，您可以使用一些微不足道的东西：

[CustomMessages]
ProgramFilesLocalized=Programme

[Code]

function ToDisplayName(Path: string): string;
begin
  StringChange(Path, '\Program Files', '\' + CustomMessage('ProgramFilesLocalized'));
  Result := Path;
end;

function FromDisplayName(Path: string): string;
begin
  StringChange(Path, '\' + CustomMessage('ProgramFilesLocalized'), '\Program Files');
  Result := Path;
end;

---

如果您需要真正实现与显示名称之间的转换，请考虑提出单独的问题。