即使进行了错误处理，Excel 错误对话框仍然会弹出

Question

我似乎遇到了一个以前没有遇到过的独特问题，无法通过谷歌找到答案。

我编写了一个小子程序来简单地打开一个包含“控制”一词的特定工作簿。

问题：尽管有一个可以工作的错误处理程序，但我从 excel 中得到一个弹出框，说它无法打开工作簿。

代码如下：

Sub OpenControlSheet(index As Integer)
Dim strFilePath As String
Dim strFileName As String

On Error GoTo ErrorHandler

strPlan = arrPlanPeriods(index)

ResumePoint:
strFilePath = "S:\Misc. Budget\" & strPlan & "\" & "*Control*"
strFileName = Dir(strFilePath)
ResumePoint2:
Set wb = Workbooks.Open("S:\Misc. Budget\" & strPlan & "\" & strFileName)

ErrorHandler:
If Err.Number <> 0 Then
    'Do stuff
End if

End sub

基本上，错误处理程序所做的是操纵文件路径，直到找到正确的名称。例如，如果“92 Pol”不起作用，请尝试“92 Poll”。但在尝试新路径之前，我总是会收到以下错误对话框：

“无法打开 'S:\Misc. Budget\92 Pol'”

然后它会通过错误处理程序并打开正确的工作簿。

我认为如果它通过错误处理程序，那么我不应该弹出任何错误对话框。知道为什么会发生这种情况吗？

Answer 1

如果在错误处理部分引发错误，它不会被任何错误处理代码捕获，并会生成标准 VBA 错误消息。

Sub errors()
On Error GoTo ErrorHandler
  x = 1 / 0
ErrorHandler:
  x = 1 / 0 ' Error message will pop up here
End Sub

现在，使用 goto 语句（我只是假设你做了类似的事情，因为你没有显示那部分代码）将不会让你 - 从逻辑上 - 脱离错误处理程序。举个例子：

Sub errors()
start:
  On Error GoTo ErrorHandler
    x = 1 / 0 ' Error will pop up here ON THE SECOND GO
ErrorHandler:
  GoTo start
End Sub

会弹出一条错误消息，即使您可以看到On Error GoTo ErrorHandler 再次被调用。 不，这不会是一个无限循环！

另一方面，使用 Resume 关键字可以从逻辑上脱离错误处理部分：

Sub errors()
  On Error GoTo ErrorHandler
    x = 1 / 0

TryAgain:
  On Error GoTo TotalFailure
  x = 1 / 0

ErrorHandler:
  Resume TryAgain

TotalFailure:
  MsgBox "Nyekk."

End Sub

因此，请确保您的错误处理代码部分不会发生错误。 VBA 在处理错误方面相当蹩脚。

尝试使用 F8 逐步浏览我的示例。

此外，此设置可能会导致一些奇怪的行为：

Answer 2

有两种方法可以解决您的问题。
第一个是使用

On Error Resume Next

On Error Resume Next 即使发生错误也会执行下一行代码，然后您可以使用检查错误

If Err.Number <> 0 Then

示例代码如下：

Sub OpenControlSheet(index)
Dim strFilePath As String
Dim strFileName As String

' Add this line above the code 
On Error Resume Next

strPlan = arrPlanPeriods(index)

strFilePath = "S:\Misc. Budget\" & strPlan & "\" & "*Control*"
strFileName = Dir(strFilePath)

' You will go through Workbooks.Open() even if error is occured
Set wb = Workbooks.Open("S:\Misc. Budget\" & strPlan & "\" & strFileName)
If Err.Number <> 0 Then
    'Do stuff
End If
End Sub

第二种方法是在打开文件之前检查文件是否存在。
当你使用

strFileName = Dir(strFilePath)

如果文件存在则返回文件名，如果文件或路径不存在则返回空字符串。

示例代码：

Sub OpenControlSheet(index)
Dim strFilePath As String
Dim strFileName As String

strPlan = arrPlanPeriods(index)

strFilePath = "S:\Misc. Budget\" & strPlan & "\" & "*Control*"
strFileName = Dir(strFilePath)

If strFileName <> "" Then
    ' Path/File exists
    Set wb = Workbooks.Open("S:\Misc. Budget\" & strPlan & "\" & strFileName)
Else
    ' Path/File not exists
    ' Do stuff
End If
End Sub

希望这能让你开心。