vba找到值然后将另一个粘贴到另一列的不同单元格中

Question

我目前正在运行一个宏，它在工作表 2 的 C 列中从“工作表 1”的 A 列中查找值，如果这些匹配，则应该将工作表 1 的 B 列中的值复制到表 2 中的相应行。

我的宏可以工作，但因为这是一个庞大的工作表，其中的循环花费了太多时间。这是因为工作表 1 大约有 300,000 行，并且每个实例中的值都是唯一的。在 Sheet 2 中大约有 50,000 行。它已经运行了一夜，到目前为止，工作表 1 中只达到了 60,000 行

我绝不是 VBA 专家，甚至不是中级专家，但从我所读到的内容来看，使用 Find 可能比查找匹配和循环更快？

这是我当前使用的宏

 Option Explicit

Sub lookupandcopy()
Application.Screenupdating = True

Dim j As Long, i As Long, lastRow1 As Long, lastRow2 As Long
Dim sh_1, sh_3 As Worksheet
Dim MyName As String

Set sh_1 = Sheets("sheet1") 
Set sh_3 = Sheets("sheet2")


lastRow1 = sh_1.UsedRange.Rows.Count 

For j = 2 To lastRow1
MyName = sh_1.Cells(j, 1).Value 


lastRow2 = sh_3.UsedRange.Rows.Count

For i = 2 To lastRow2
    If sh_3.Cells(i, 3).Value = MyName Then
        sh_3.Cells(i, 13).Value = sh_1.Cells(j, 2).Value 
    End If

    Next i

  Next j

Application.Screenupdating = True
End Sub

如果我遗漏了任何内容或任何其他需要的细节，请告诉我！

Answer 1

您似乎将 sheet1 中的 A 列和 B 列用作字典（并通过线性搜索访问值）。为什么不将值加载到具有 O(1) 搜索的字典对象中？确保您的项目包含对 Microsoft Scripting Runtime 的引用（如果您没有做过这些事情，则在 VBE 中使用工具 > 引用）然后尝试：

Sub lookupandcopy()
    Application.ScreenUpdating = False

    Dim AVals As New Dictionary
    Dim i As Long, j As Long, lastRow1 As Long, lastRow2 As Long
    Dim sh_1, sh_3 As Worksheet
    Dim MyName As String

    Set sh_1 = Sheets("sheet1")
    Set sh_3 = Sheets("sheet2")

    With sh_1
        lastRow1 = .Range("A:A").Rows.Count 'last row in spreadsheet
        lastRow1 = .Cells(lastRow1, 1).End(xlUp).Row 'last used row in column A
        'load the AVal dict
        For j = 2 To lastRow1
            MyName = .Cells(j, 1).Value
            If Len(MyName) > 0 Then AVals.Add MyName, .Cells(j, 2).Value
        Next j
    End With

    With sh_3
        lastRow2 = .Range("A:A").Rows.Count
        lastRow2 = .Cells(lastRow2, 3).End(xlUp).Row 'last used row in column 3
        For i = 2 To lastRow2
            MyName = .Cells(i, 3).Value
            If AVals.Exists(MyName) Then
                .Cells(i, 13).Value = AVals.Item(MyName)
            End If
         Next i
    End With
    Application.ScreenUpdating = True
End Sub

如果您在 A 列中有重复的值，那么您需要执行一些操作，例如将值发生的行索引的值集合存储为值，但设置这样一个字典的工作仍然比使用嵌套循环更好。