Excel VBA On Error Resume Next 返回值超出位置

Question

我正在使用 URL 将图片放在我的工作表中。该代码工作得很好，除了“on error resume next”将前一个单元格的（良好）值放在发生错误的单元格中，而不是它应该的单元格中（一行向上）。然后它继续将值放在它们所属的位置，直到出现另一个错误。

我尝试将“on error resume next”放置在代码的不同区域，但无法解决问题。是错误处理放置在哪里的问题，还是我需要更好的错误处理程序？

谢谢， 安迪

Sub InsertPic()
  On Error Resume Next 
  Dim pic As String 
  Dim myPicture As Picture 
  Dim rng As Range 
  Dim cl As Range 

Set rng = Range("F2:F1131")
For Each cl In rng
pic = cl.Offset(0, -1)

Set myPicture = ActiveSheet.Pictures.Insert(pic)

With myPicture

    .ShapeRange.LockAspectRatio = msoFalse
    .Width = cl.Width
    .Height = cl.Height
    .Top = Rows(cl.Row).Top
    .Left = Columns(cl.Column).Left
End With

Next

End Sub

Answer 1

如果您需要检查 URL 是否存在，那么也许一个辅助函数就足够了？

Sub InsertPic()

  Dim pic As String 
  Dim myPicture As Picture 
  Dim rng As Range 'E3:E1132
  Dim cl As Range 'iterator

  Set rng = Range("F2:F1131")
  For Each cl In rng
    pic = cl.Offset(0, -1)

    if URLExists(pic) then
      Set myPicture = ActiveSheet.Pictures.Insert(pic)
      With myPicture
        .ShapeRange.LockAspectRatio = msoFalse
        .Width = cl.Width
        .Height = cl.Height
        .Top = Rows(cl.Row).Top
        .Left = Columns(cl.Column).Left
      End With
    end if
  Next

End Sub

'ref: http://www.mrexcel.com/forum/excel-questions/567315-check-if-url-exists-so-then-return-true.html
Function URLExists(url As String) As Boolean
    Dim Request As Object
    Dim ff As Integer
    Dim rc As Variant

    On Error GoTo EndNow
    Set Request = CreateObject("WinHttp.WinHttpRequest.5.1")

    With Request
      .Open "GET", url, False
      .Send
      rc = .StatusText
    End With
    Set Request = Nothing
    If rc = "OK" Then URLExists = True

    Exit Function
EndNow:
End Function