如何避免这种重复的代码？

Question

我有一堆用于工作表的子例程，它们的开始和结束方式都完全相同。它们基本上都遍历表中的每一行并对每一行执行一些独特的操作。我不希望它们每次都运行，而是希望能够单独调用它们。

实际代码如下所示：

Sub randomSub()
    Dim finalRow As Long
    Dim i As Long

    finalRow = Sheet.Cells(Rows.count, Column).End(xlUp).row

    With Sheet2
        For i = 3 To finalRow
            ' Do some random operations here
        Next i
    End With
End Sub

将代码设置为循环遍历每一行并不难，但在 4 或 5 个不同的潜艇上重复它之后，我想有更好的方法。

所以我想我的问题是这样的：有没有一种最佳做法可以避免为我制作的每个新子程序一遍又一遍地编写这样的循环设置？

编辑：这是我正在执行的操作类型的一些示例，通常会替换 ' Do random operations here

Sub moveToFront()
    Dim stringHolder() As String

    stringHolder = Split(Sheet2.Cells(i, 11), "; ")
    If stringHolder(1) = "" Then
        .Cells(i, 11) = stringHolder(0)
    Else
        .Cells(i, 11) = stringHolder(1) & "; " & stringHolder(0)
    End If
End Sub

还有一个

Sub fillInTotals()
    If .Cells(i, 3) <> "" Then
        .Cells(i, 1) = "='EUS Graph'!$C$" & _
            Application.WorksheetFunction.Match(.Cells(i, 3), Sheet4.Range("$A:$A"), 0)
    Else
        .Cells(i, 1) = "='EUS Graph'!$C$"
    End If
End Sub

Answer 1

考虑使用通用的用户定义函数并将其放置在所有宏都可以访问它的位置，ThisWorkbook 部分或标准模块：

Public Function randomSub(SheetName As String, ColumnLetter As String, _
                          OperationType As String)
    Dim wsh As Worksheet
    Dim i As Long, finalRow As Long
    Dim stringHolder() As String

    Set wsh = ThisWorkbook.Worksheets(SheetName)

    With wsh
        finalRow = wsh.Cells(wsh.Rows.Count, ColumnLetter).End(xlUp).Row
        For i = 3 To finalRow                              
             Select Case OperationType

                 Case "MoveToFront"
                    stringHolder = Split(Sheet2.Cells(i, 11), "; ")
                    If stringHolder(1) = "" Then
                        .Cells(i, 11) = stringHolder(0)
                    Else
                        .Cells(i, 11) = stringHolder(1) & "; " & stringHolder(0)
                    End If

                 Case  "fillInTotals"
                    If .Cells(i, 3) <> "" Then
                            .Cells(i, 1) = "='EUS Graph'!$C$" & _
                                     Application.WorksheetFunction.Match(.Cells(i, 3), _
                                     Sheet4.Range("$A:$A"), 0)
                    Else
                            .Cells(i, 1) = "='EUS Graph'!$C$"
                    End If

             End Select
        Next i
    End With
End Function

然后，根据需要调用函数，传递所需参数：

Call randomSub(ActiveSheet.Name, "A", "MoveToFront")