避免 XSLT 输出中的空元素

Question

我想将一个输入 XML 映射到另一个 XML，只需将输入中的值写入输出中的不同标签。

举个简单的例子，如下：

<root1>
  <a1>valA<a1>
  <b1>valB<b2>
</root1>

需要成为：

<root2>
  <a2>valA</a2>
  <b2>valB</b2>
</root2>

目前我的 XSLT 中有以下内容：

<xsl:apply-templates match="root1" />

<xsl:template match="root1">
  <a2>
    <xsl:value-of select="a1" />
  </a2>
  <b2>
    <xsl:value-of select="b1" />
  </b2>
</xsl:template>

问题是我不想在我的输出中出现空标签。如果valA 和valB 为空，我会得到：

<root2>
  <a2></a2>
  <b2></b2>
<root2>

但我想省略空标签。我原以为xsl:output 可能有一个属性，但没有......我在 SO 上遇到了这个问题：XSLT: How to exclude empty elements from my result? - 但答案是间接的，它指定了一个 second样式表在第一次转换后去除空的输出元素。

我需要使用一个样式表来完成此操作。肯定有比做更简洁的事情：

<xsl:if test="string-length(a1) != 0">
  <a2>
    <xsl:value-of select="a1" />
  </a2>
</xsl:if>

甚至：

<xsl:template match="a1[string-length(.) != 0]">
  <a2>
    <xsl:value-of select="." />
  </a2>
</xsl:template>

对每个元素重复？？

Answer 1

在我看来，您的尝试很好，尽管许多人使用而不是测试字符串长度，例如<xsl:template match="a1[normalize-space()]"><a2><xsl:value-of select="."/></a2></xsl:template> 代替。但是如果你需要检查一个元素是否为空，那么你需要一些谓词或测试表达式，没有可以全局打开的设置。

Answer 2

你可以做的是有一个通用模板匹配任何没有文本的“叶子”元素，然后忽略这样的元素

<xsl:template match="*[not(*)][not(normalize-space())]" />

您可以将其与仅匹配 a1、b1 元素且不带任何条件的模板组合，这样您就可以像当前一样转换为 a2、b2

试试这个 XSLT

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" />

  <xsl:template match="@*|node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="root1">
    <root2>
      <xsl:apply-templates select="@*|node()"/>
    </root2>
  </xsl:template>

  <xsl:template match="a1">
    <a2>
      <xsl:apply-templates select="@*|node()"/>
    </a2>
  </xsl:template>

  <xsl:template match="b1">
    <b2>
      <xsl:apply-templates select="@*|node()"/>
    </b2>
  </xsl:template>

  <xsl:template match="*[not(*)][not(normalize-space())]" />
</xsl:stylesheet>

请注意 XSLT 标识模板的使用，在您的特定示例中不需要该模板，因为您正在重命名所有元素，但如果您确实希望保持某些元素相同，则会使用该模板。

Answer 3

另一种方法是“延迟”输出输出。 让我解释。通过将输出放入变量中，可以防止输出开始输出，然后使用 copy-of 最终可以输出输出，但要小心使用过滤空标签的 XPath 表达式，如下所示：

假设您的源 XML 是：

<root1>
  <a1>valA</a1>
  <b1>valB</b1>
  <c1>valC</c1>
  <d1></d1>
  <e1>valE</e1>
  <f1></f1>
</root1>

然后您可以将输出放入变量中，而无需关心 xsl:if 检查或模板匹配：

<xsl:template match="/root1">
    <xsl:variable name="output" as="node()*">
        <a1><xsl:value-of select="a1"/></a1>
        <b1><xsl:value-of select="b1"/></b1>
        <c1><xsl:value-of select="c1"/></c1>
        <d1><xsl:value-of select="d1"/></d1>
        <e1><xsl:value-of select="e1"/></e1>
        <f1><xsl:value-of select="f1"/></f1>
    </xsl:variable>

    <root1>
        <xsl:copy-of select="$output[text()]"/>
    </root1>
</xsl:template>

使用 $output[text()] 允许您只保留具有文本内容的标签。

此外，如果您想应用于所有标签，您可以使用 xsl:for-each 循环来自动化一点：

<xsl:template match="/">
    <xsl:variable name="output" as="node()*">
        <xsl:for-each select="./*">
            <xsl:element name="{name(.)}">
                <xsl:value-of select="."/>
            </xsl:element>
        </xsl:for-each>
    </xsl:variable>

    <root1>
        <xsl:copy-of select="$output[text()]"/>
    </root1>
</xsl:template>