XSLT：为父子关系使用密钥

Question

假设每个第一个“Section”->“typeAttr”都是第二个的子项（A 是父项，B 是子项），当然它们与其他“类型”相关。如何使用 xsl 并将其转换为 html？

<root>
<Type>
    <Section typeAttr="B"/>
    <Section typeAttr="A"/>
</Type>
<Type>
    <Section typeAttr="C"/>
    <Section typeAttr="B"/>
</Type>
<Type>
    <Section typeAttr="D"/>
    <Section typeAttr="B"/>
</Type> 
<Type>
    <Section typeAttr="E"/>
    <Section typeAttr="C"/>
</Type>     
</root> 

类似这样的：

<ol>
<li>
    <a>A</a>
    <ol>
        <li>
            <a>B</a>
            <ol>
                <li><a>C</a>
                    <ol>
                        <li>
                            <a>E</a>
                        </li>
                    </ol>
                </li>
                <li>
                    <a>D</a>
                </li>
            </ol>
        </li>
    </ol>
</li>
</ol>

Answer 1

我相信这会返回预期的结果：

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" omit-xml-declaration="yes" version="1.0" encoding="utf-8" indent="yes"/>

<xsl:key name="children" match="Type" use="Section[2]/@typeAttr" />
<xsl:key name="parent" match="Type" use="Section[1]/@typeAttr" />

<xsl:template match="/root">
    <ol>
        <xsl:apply-templates select="Type[not(key('parent', Section[2]/@typeAttr))]" mode="ancestor"/>
    </ol>
</xsl:template>

<xsl:template match="Type" mode="ancestor">
    <li>
        <a>
            <xsl:value-of select="Section[2]/@typeAttr"/>
        </a>
        <ol>
            <xsl:apply-templates select="."/>
        </ol>
    </li>
</xsl:template>

<xsl:template match="Type">
    <li>
        <a>
            <xsl:value-of select="Section[1]/@typeAttr"/>
        </a>
        <xsl:variable name="children" select="key('children', Section[1]/@typeAttr)" />
        <xsl:if test="$children">
            <ol>
                <xsl:apply-templates select="$children"/>
            </ol>
        </xsl:if>
    </li>
</xsl:template>

</xsl:stylesheet>