Sparql 关于 dbpedia:World_Wide_Web

Question

我是语义网的新手，我正试图弄清楚如何编写一个 SPARQL 查询以从 dbpedia 中提取有关特定主题的所有信息。不仅是礼节，还有与之相关的一切。

我什至不知道如何开始这样的查询。

我想获得有关万维网的所有三元组。

PREFIX dbpedia: <http://dbpedia.org/resource/>

SELECT DISTINCT ?s ?p ?o 
WHERE  {
  ?s ?p ?o .
  ?s ?p dbpedia:World_Wide_Web  

  #  FILTER( lang(?s) = "en" )   -- doesn't work with filter

}Limit 100

这只会返回一些带有 owl:sameAs 谓词的三元组

你能帮帮我吗？

Answer 1

您可以通过这样的查询获得所有以dbpedia:World_Wide_Web 作为主语或宾语的三元组（当然，这只给出 1000）。对于任何是字面量的对象，我们可以限制它们的语言值：

select ?s ?p ?o where {
  values ?web { dbpedia:World_Wide_Web }
  { ?web ?p ?o bind( ?web as ?s ) } union
  { ?s ?p ?web bind( ?web as ?o ) }

  # for literal objects, take only English ones
  filter( !isLiteral(?o) || langMatches(lang(?o),'en') )
}
limit 1000

SPARQL results

这包括如下结果，这似乎与您在 cmets 中提到的一致：

http://dbpedia.org/resource/World_Wide_Web  http://dbpedia.org/property/company  http://dbpedia.org/resource/CERN
http://dbpedia.org/resource/World_Wide_Web  http://dbpedia.org/property/inventor  http://dbpedia.org/resource/Tim_Berners-Lee

这将产生 很多 的结果，因此您可能希望限制可以使用的属性。您应该能够执行以下操作，但是在当前的 DBpedia 端点上，它会导致错误。

select ?s ?p ?o where {
  values ?web { dbpedia:World_Wide_Web }
  values ?p   { rdf:type dbpedia-owl:abstract }

  { ?web ?p ?o bind( ?web as ?s ) } union
  { ?s ?p ?web bind( ?web as ?o ) }
}
limit 1000

Virtuoso 37000 Error SP031: SPARQL compiler: Internal error: sparp_gp_attach_filter_cbk(): attempt to attach a filter with used variable

SPARQL query:
define sql:big-data-const 0 
#output-format:text/html
define sql:signal-void-variables 1 define input:default-graph-uri <http://dbpedia.org> select ?s ?p ?o where {
  values ?web { dbpedia:World_Wide_Web }
  values ?p   { rdf:type dbpedia-owl:abstract }

  { ?web ?p ?o bind( ?web as ?s ) } union
  { ?s ?p ?web bind( ?web as ?o ) }
}
limit 1000

作为一种解决方法，您可以这样做：

select ?s ?p ?o where {
  values ?web { dbpedia:World_Wide_Web }

  { ?web ?p ?o bind( ?web as ?s ) }
  union
  { ?s ?p ?web bind( ?web as ?o ) }

  filter( ?p in (rdf:type, dbpedia-owl:abstract ))  ###
}
limit 1000

SPARQL results