使用关系运算符的 SPARQL 查询

Question

我想对 SPARQL 查询使用关系 AND/OR 运算符。

这里查询：

SELECT DISTINCT ?dbpedia_link str(?name) as ?label str(?label1) as ?label1 ?freebase_link WHERE {
            ?dbpedia_link rdfs:label ?label1 . 
            ?dbpedia_link foaf:name ?name .
            {
                { ?dbpedia_link rdf:type dbpedia-owl:Film .}
                UNION
                { ?dbpedia_link rdf:type dbpedia-owl:Person .}
            }
            ?dbpedia_link owl:sameAs ?freebase_link .
            FILTER regex(?freebase_link, "^http://rdf.freebase.com") .
            FILTER (lang(?label1) = 'en'). 
            ?name bif:contains "Akshay_Kumar" . 
            ?dbpedia_link dcterms:subject ?sub 
        }

在这个查询中，我使用了Akshay_Kumar，这是一个单一的名字。现在我想要那个，我如何使用关系 AND/OR 运算符同时放置多个名称。简而言之，我们如何在 sparql 中使用关系运算符。

正在执行 sparql 查询 URL：http://dbpedia.org/sparql

Answer 1

连接

AND 很简单。如果你想说 X 通过属性 P 与 Y 相关，并且通过属性 Q 与 Z 相关，你只需包含两个三元组：

X P Y .
X Q Z .

可以缩写：

X P Y ; QZ。

现在，如果属性相同，那么你说 X 通过属性 P 与 Y 和 Z 相关，它变成：

X P Y ;
  P Z .

SPARQL 提供了一个简写（它与 RDF 的 Turtle 序列化共享）：

X P Y, Z .

析取

OR 有点复杂，但您已经展示了一种方法。如果你想说 X 与 任何一个 Y 或 Z 有关，你可以这样做：

{ X P Y } UNION { X P Z }

SPARQL 1.1 包含 VALUES，这可以使这更简单：

VALUES ?xpValue { Y Z }
X P ?xpValue

更新您的查询

您的查询实际上不是合法的 SPARQL 1.1（或 SPARQL），即使 Virtuoso（DBpedia 运行的端点）接受它。您可以使用sparql.org's query validator 进行测试。另请注意，您使用的是bif:contains，它提供了一个字符串包含函数，但SPARQL 1.1 实际上提供了一个您可以使用的contains 函数。它还提供了strstarts，您可以使用它来更有效地识别freebase 链接。它还提供langMatches，这是检查字符串语言标签的正确方法。使用这些，我将重写您的查询，如下所示，它会查找名称包含“John”或“Mary”的资源。 （限制只是为了让这个例子的结果简短。）

select ?resource ?name ?label ?freebase where {
  values ?type { dbpedia-owl:Film dbpedia-owl:Person }
  values ?namePart { "John" "Mary" }

  ?resource rdfs:label ?label ;
            foaf:name ?name ;
            a ?type ;
            owl:sameAs ?freebase .

  filter ( langMatches( lang(?label), 'en' ) &&
           strstarts(str(?freebase), "http://rdf.freebase.com" ) &&
           contains( ?name, ?namePart ) )
}
limit 10

SPARQL results