如何在 MS-Word 中删除不同格式的段落标记

Question

我有一些由段落标记分隔的行，但实际上它们属于同一段落。

问题是文本是 Arial 15 斜体，但有些单词不是斜体（显示为红色），段落标记是 Arial 15 斜体，而不是斜体，甚至 Calibri 11。这意味着，并非所有段落标记都有相同的格式。

我想用空格“”替换段落标记，以便仅在单个段落中加入 Arial、15 斜体的连续行组 即使它们没有斜体。

到目前为止我尝试过：

查找内容：^p（格式：Arial 15，斜体） 替换为：“”

但是这样做只会找到以绿色显示的段落标记。

在输入格式的图像和我想要作为输出的图像下方。另外我附上了一个示例文件Sample.docx。

感谢您的帮助

Answer 1

试试

Option Explicit
Sub ReplacePara()
Dim Para As Paragraph, Xstr As String, Rng As Range
Dim i As Long, ln As Long
Dim PrvChrSize As Integer, NextChrSize  As Integer
Dim PrvChrFont As String, NextChrFont  As String
Dim PrvChrItalic As Boolean, NextChrItalic As Boolean

    With ActiveDocument
    For i = .Paragraphs.Count To 1 Step -1
    Set Para = .Paragraphs(i)
    ln = Para.Range.Characters.Count

        If ln > 1 Then
            With Para.Range.Characters(ln - 1).Font
            PrvChrSize = .Size
            PrvChrFont = .Name
            PrvChrItalic = .Italic
            End With

            If i < .Paragraphs.Count Then
                With .Paragraphs(i + 1).Range.Characters(1).Font
                NextChrSize = .Size
                NextChrFont = .Name
                NextChrItalic = .Italic
                End With
            Else
            NextChrSize = 0
            NextChrFont = ""
            NextChrItalic = False
            End If
        End If

        Debug.Print i, PrvChrSize, PrvChrFont, NextChrSize, NextChrFont
        If (PrvChrSize = 15 And (PrvChrFont = "Arial" Or PrvChrItalic = True)) _
        And (NextChrSize = 15 And (NextChrFont = "Arial" Or NextChrItalic)) Then
        Para.Range.Characters(ln).Text = " "
        End If
    Next
  End With

End Sub

示例文件的结果：