Excel VBA - 添加具有特定标题名称的新表格列

Question

我有一个简单的 vba 问题。我想要一个宏，它将在我的表对象（“Table1”）中添加正好 4 个新列。我也希望这些按从左到右的顺序命名：

AHT、目标 AHT、传输、目标传输

我下面的代码很好地添加了列，但我不确定如何单独命名。另外，有人可以告诉我如何循环那段代码。谢谢！

Sub insertTableColumn()
Dim lst As ListObject
Dim currentSht As Worksheet

Set currentSht = ActiveWorkbook.Sheets("Sheet1")
Set lst = ActiveSheet.ListObjects("Table1")

'below is the code that I would like to have looped
    lst.ListColumns.Add
    lst.ListColumns.Add
    lst.ListColumns.Add
    lst.ListColumns.Add

End Sub

Answer 1

变量数组是将变量存储在循环序列中的好地方。

Sub insertTableColumn()
    Dim lst As ListObject
    Dim currentSht As Worksheet
    Dim h As Long, hdrs As Variant

    hdrs = Array("AHT", "Target AHT", "Transfers", "Target Transfers")

    Set currentSht = ActiveWorkbook.Sheets("Sheet1")
    Set lst = ActiveSheet.ListObjects("Table1")

    With lst 'ActiveSheet.ListObjects("Table1")
        For h = 0 To 3
            .ListColumns.Add
            .ListColumns(.ListColumns.Count).Name = hdrs(h)
        Next h
    End With

End Sub

以这种方式创建字符串数组时，请记住变量数组的索引默认情况下是从零开始的。

Answer 2

以下代码会创建一个包含您要添加的列名的数组，然后根据要添加的标题循环多次并同时设置名称。

Sub insertTableColumn()
Dim lst As ListObject
Dim currentSht As Worksheet

Set currentSht = ActiveWorkbook.Sheets("Sheet1")
Set lst = ActiveSheet.ListObjects("Table1")
ColumnNames = Array("AHT", "Target AHT", "Transfers", "Target Transfers")

' below is the code that I would like to have looped
For iLoop = 0 to UBound(ColumnNames)
    Set oLC = lst.ListColumns.Add
    oLC.Name = ColumnNames(iLoop)
Next

End Sub