如何计算目录和子文件夹中所有文本文件的行数

Question

我正在尝试改进@Tony 在other question 中发布的脚本

  @Echo off
  Set _File=file.txt
  Set /a _Lines=0
  For /f %%j in ('Type %_File%^|Find "" /v /c') Do Set /a _Lines=%%j
  Echo %_File% has %_Lines% lines.

计算目录和子文件夹中所有文本文件的行数：

  @Echo off
  setlocal EnableDelayedExpansion
  Set _Dir=C:\TEST_DIR\
  Set /a _Lines=0
  for /R %_Dir% %%f in (*.*) do (
    for /f %%j in ('Type !%%f!^|Find "" /v /c') Do Set /a _Lines=!_Lines!+!%%j!
  )
  Echo %_Dir% has %_Lines% lines.
  pause

但我收到错误：“缺少操作数。”

Answer 1

我的错，我在句子中使用了额外的!!：

Do Set /a _Lines=!_Lines!+!%%j!

这是工作代码：

@Echo off
Set _Dir=C:\TEST_DIR\
Set /a _Lines=0
for /R %_Dir% %%f in (*.*) do (
  for /f %%j in ('Find "" /v /c ^< "%%~f"') Do Set /a _Lines=_Lines+%%j
)
Echo %_File% has %_Lines% lines.
pause

[已编辑] @aschipfl 建议

Answer 2

我发现了一些问题。

首先，正如您刚刚在我键入此内容时发现的那样，您得到了缺少的操作数，因为您在 !%%j! 上使用了延迟扩展，而您不需要。 Type !%%f!... 上也不需要它。事实上，它不适用于有空格的文件。我建议将其更改为 Type "%%~f"... 以允许文件名中包含空格。

一般来说，您可以通过使用echo 来发现这些问题，以查看命令是如何被解释的。例如，复制这一行，在Do 之后插入一个echo。问题变得很明显。

for /f %%j in ('Type !%%f!^|Find "" /v /c') Do echo Set /a _Lines=!_Lines!+!%%j!

另外，请注意，如果您在二进制文件上使用它，您可能会得到意想不到的结果。考虑在for /r 行中使用不同的文件掩码（或一组文件掩码）而不是*.*。例如：

for /R %_Dir% %%f in (*.txt *.xml *.ini) do (