为 /L 循环嵌套的批处理文件并退出它们

Question

SETLOCAL ENABLEDELAYEDEXPANSION
set list=A B C D E

FOR %%a IN (%list%) DO (
    start %%a.exe > ouput_%%a.txt
    echo 120, 30 second loops = 60 min
    FOR /L %%i IN (1,1,120) DO (
        REM pause for 30 seconds
        ping 1.1.1.1 -n 1 -w 30000 > nul

        echo find the running executable
        tasklist | findstr %%a.exe > nul
        REM !ERRORLEVEL!
        REM exit the script if no executable is found (i.e it has run successfully)
        if !ERRORLEVEL! equ 1 goto success
   )
   REM kill executable if we haven't exited yet
   taskkill /f /im %%a.exe
   :success
)

这段代码没有像我期望的那样通过 for 循环。我试图做这样的事情 How to break inner loop in nested loop batch script ，但无济于事。有什么建议吗？

编辑

当可执行文件完成运行时，ERRORLEVEL 不为 1。

SETLOCAL ENABLEDELAYEDEXPANSION
set list=A B C D E

FOR %%a IN (%LIST%) DO (
    start %%a.exe > ouput_%%a.txt
    REM 120, 30 second loops = 60 min
    call :innerloop %%a
    REM kill executable if we haven't exited yet
    taskkill /f /im %%a.exe
)
goto :eof
:innerloop
FOR /L %%i IN (1,1,120) DO (
    REM pause for 30 seconds
    ping 1.1.1.1 -n 1 -w 30000 > nul

    REM find the running executable
    tasklist | findstr %%a.exe > nul
    REM !ERRORLEVEL!
    REM exit the script if no executable is found (i.e it has run successfully)
    if %ERRORLEVEL% equ 1 goto :next
)
:next
goto :eof

Answer 1

在for 循环内执行goto 命令会中断循环迭代。这适用于 所有 嵌套的 for 循环。

但是，您可以将您的内部 for 循环移动到子例程中（使用 call 调用它）。这个循环可以被goto命令终止，但是从子程序返回后，剩余的（外层）for循环不受影响，继续迭代。

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION
set list=A B C D E

FOR %%a IN (%list%) DO (
    start %%a.exe > ouput_%%a.txt
    echo 120, 30 second loops = 60 min
    REM kill executable if we haven't exited yet
    call :SUBLOOP %%a.exe && taskkill /f /im %%a.exe
)
exit /B

:SUBLOOP
FOR /L %%i IN (1,1,120) DO (
    REM pause for 30 seconds
    timeout /T 30 /NOBREAK > nul
    echo find the running executable
    tasklist | findstr /I /B "%~1" > nul
    REM !ERRORLEVEL! is 0 if found and 1 otherwise
    REM exit the script if no executable is found
    REM (i.e it has run successfully)
    if !ERRORLEVEL! equ 1 goto :EOF
)
exit /B 0

在这里，我将内部for 循环移动到一个子例程:SUBLOOP，由call :SUBLOOP %%a.exe 从其以前的代码部分调用，将当前值从外部传递给进程（可执行文件%%a.exe） for 循环到它。 ERRORLEVEL 在终止时转移到调用例程。
从:SUBLOOP返回到外部for循环后，检查ERRORLEVEL是否为零，如果是，则杀死当前迭代的可执行程序的进程。 && 是一个条件命令分隔符，它仅在第一个命令成功时执行第二个命令，也就是说，如果 ERRORLEVEL 被清除。
请注意外部for 循环之后的exit /B 命令，这是在外部循环完成后不无意执行SUBLOOP 部分所必需的。

注意：
goto 不会立即终止for 循环迭代；实际上，每个待处理的迭代仍然会被静默计数，但不会再执行 for 正文的命令。因此，具有大量迭代的循环可能需要相当长的时间才能继续执行批处理。谢谢@foxidrive 这个useful information！
此外，如果goto 目标标签放置在for 正文中，则在循环完全完成后继续执行该点。然后，该点之后的任何代码都被视为“正常”代码，而不是 for 正文的一部分。