使用“for /f”从命令输出中保存多个标记

Question

This 答案是我想要做的，但它适用于字符串 NOT 命令输出。

我的脚本是：

@echo off 
setlocal enabledelayedexpansion

for /F "skip=1 tokens=1,3,5,7" %%a in ('adb devices') do (
echo %%a

set dev1=%%a
set dev2=%%b
set dev3=%%c
set dev4=%%d
)
echo.
echo Devices are: !dev1!, !dev2!, !dev3!, !dev4!
pause

但它显示的是 1 个设备，而不是 2 个可用的设备：

770a56
emulator-5554

Devices are: emulator-5554, , ,
Press any key to continue . . .

来自 Windows 的示例输出：

C:\Windows\Right\Console2>adb devices
List of devices attached
BH90W3T416      device
HSMPG9265D606183        device
emulator-5554   device

Answer 1

为了存储几个值，每一个在自己的变量中当这样一个数字事先不知道的时候（如果有2个为什么要用4个变量呢？设备？），您需要使用array：

@echo off 
setlocal enabledelayedexpansion

set n=0
for /F "skip=1" %%a in ('adb devices') do (
   echo %%a

   set /A n+=1
   set dev!n!=%%a
)
echo/
echo Devices are: 
for /L %%i in (1,1,%n%) do echo !dev%%i!
pause

Answer 2

...
set dev1=!dev1!,%%a
set dev2=!dev2!,%%b
set dev3=!dev3!,%%c
set dev4=!dev4!,%%d
...
echo Devices are: !dev1:~1!, !dev2:~1!, !dev3:~1!, !dev4:~1!

这将为每个 dev 建立一个列表，并以逗号开头。

由于您没有向我们显示原始输入，也没有解释为什么您指定 4 个标记但只显示一个，因此您的问题不清楚。如果%%a 是唯一感兴趣的令牌，那么

...
set "dev4=!dev3!"
set "dev3=!dev2!"
set "dev2=!dev1!"
set "dev1=%%a"
...

可能更合适。