创建原始工作簿的副本，从列表中输入新数据

Question

尝试复制我的原始工作表，但对于列表/数组中的多个项目使用不同的数据。

我的原始工作表的格式设置为引用数据数组工作表中的单元格。

例如

TEST TIME Output1 Output2

   A        3         5           9  
   .        .         .           .
   .        .         .           .
   .        .         .           .
   Z        2         9           4

上面将类似于我的数据数组工作表，我会将单元格引用到格式化的工作表。最终结果将是 26 个名为 A 测试、B 测试、...和 ​​Z 测试的工作表。

有没有办法一遍又一遍地复制工作表，在数组中创建新的参考单元格？

我有什么：

Sub AddSheets()
Dim cell As Excel.Range
Dim SCHPipe As Excel.Worksheet
Dim MacroTBF1 As Excel.Workbook

Set SCHPipe = ActiveSheet
Set MacroTBF1 = ActiveWorkbook
For Each cell In SCHPipe.Range("B12:B15")
    With MacroTBF1
   .Sheets("OriginalTBF").Copy after:=.Sheets(.Sheets.Count)
   End If

Next cell
End Sub

我不知道如何将数据引用到正在创建的每个工作表。这不断收到无效的错误消息。

Answer 1

类似这样，您需要调整数据和模板表的布局：

Sub AddSheets()
    Dim cell As Range
    Dim SCHPipe As Worksheet, shtOrig As Worksheet
    Dim MacroTBF1 As Workbook, shtNew As Worksheet


    Set SCHPipe = ActiveSheet
    Set MacroTBF1 = ActiveWorkbook
    Set shtOrig = MacroTBF1.Sheets("OriginalTBF")


    For Each cell In SCHPipe.Range("B12:B15")

        If cell.Value <> "" Then

            shtOrig.Copy after:=MacroTBF1.Sheets(MacroTBF1.Sheets.Count)
            Set shtNew = MacroTBF1.Sheets(MacroTBF1.Sheets.Count)

            With shtNew
                .Name = cell.Value & " Test"
                .Range("A1").Value = cell.Value
                .Range("A2").Value = cell.Offset(0, 1).Value
                .Range("D49").Value = IIf(cell.Offset(0, 1).Value = "-", _
                                          cell.Offset(0, 5).Value, "")
            End With
        End If

    Next cell
End Sub