根据单元格的值在 Excel 中隐藏和显示多列

Question

我正在尝试根据某个单元格中的值将列隐藏在工作表中。该值的范围可以是不同的名称选项，并且为每个可能的选项隐藏不同的列。我有以下代码，但它似乎并不总是有效，然后有时它只隐藏范围内的一些列，但不是全部（比如如果 Abandonnée 在单元格 F7 中，那么有时 H 列会隐藏我不会被隐藏）。如果有人有任何想法，我将不胜感激。谢谢！

Private Sub Worksheet_SelectionChange(ByVal Target As Range)  
If Range("F7").Value = "Abandonnée" Then  
    Columns("G").EntireColumn.Hidden = False  
Else  
    Columns("G").EntireColumn.Hidden = True  
End If  

If Range("F7").Value = "Abandonnée" Then  
    Columns("H:I").EntireColumn.Hidden = True  
Else  
    Columns("H:I").EntireColumn.Hidden = False  
End If  

If Range("F7").Value = "Référé au spécialiste" Then  
    Columns("G").EntireColumn.Hidden = True  
Else  
    Columns("G").EntireColumn.Hidden = False  
End If  

If Range("F7").Value = "Référé au spécialiste" Then  
    Columns("H").EntireColumn.Hidden = False  
Else  
    Columns("H").EntireColumn.Hidden = True  
End If 

If Range("F7").Value = "Référé au spécialiste" Then  
    Columns("I").EntireColumn.Hidden = True  
Else  
    Columns("I").EntireColumn.Hidden = False  
End If  

If Range("F7").Value = "En force" Then  
    Columns("G").EntireColumn.Hidden = True  
Else  
    Columns("G").EntireColumn.Hidden = False  
End If  

If Range("F7").Value = "En attente d'information" Then  
    Columns("G").EntireColumn.Hidden = True  
Else  
    Columns("G").EntireColumn.Hidden = False  
End If  

If Range("F7").Value = "En cours" Then  
    Columns("G").EntireColumn.Hidden = True  
Else  
    Columns("G").EntireColumn.Hidden = False  
End If 

If Range("F7").Value = "Refusé par l'assureur" Then  
    Columns("G").EntireColumn.Hidden = True  
Else  
    Columns("G").EntireColumn.Hidden = False  
End If  

End Sub

Answer 1

两件事：

1. 首先取消隐藏所有列。

2. 然后使用 Select Case 遍历条件，隐藏需要隐藏的内容。

像这样，你需要输入其他条件：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
Columns("G:I").Hidden = False
Select Case Range("F7")
    Case "Abandonnée"
        Columns("H:I").Hidden = True
    Case "Référé au spécialiste"
        Columns("G").EntireColumn.Hidden = True
        Columns("I").EntireColumn.Hidden = True
    Case "En force"
        Columns("G").EntireColumn.Hidden = True
    'Continue with all your tests
End Select


End Sub

如果您有触发隐藏相同列的单词，您可以像您的 Case 语句一样执行此操作：

Case "En force","Abandonnée"
     '...

然后当 F7 是这两个中的一个时，它将执行以下操作。