Perl 脚本重命名名称中带有空格的文件，pushd/popd 等效？答案

【问题标题】：Perl script to rename files with spaces in name, pushd/popd equivalent?Perl 脚本重命名名称中带有空格的文件，pushd/popd 等效？
【发布时间】：2013-10-16 01:34:46
【问题描述】：

我的 Linux 系统挂载了一些 Samba 共享，一些文件是由 Windows 用户存放的。这些文件的名称有时包含空格和其他不需要的字符。将这些字符更改为连字符- 似乎是一个合理的解决方案。无需更改任何其他内容即可处理这些已清理的文件名。

几个问题，

除了空格、括号还有哪些字符需要翻译？
应该检查哪些其他文件属性（除了文件类型（文件/目录）和权限）？
Perl 是否提供pushd/popd 等效项，或者chdir 是遍历目录树的合理解决方案吗？

这是我的 Perl 程序

#!/bin/env perl
use strict;
use warnings;

use File::Copy;

#rename files, map characters (not allowed) to allowed characters
#map [\s\(\)] to "-"

my $verbose = 2;
my $pat     = "[\\s\\(\\)]";

sub clean {
  my ($name) = @_;
  my $name2 = $name;
  $name2 =~ s/$pat/\-/g;

  #skip when unchanged, collision
  return $name if (($name eq $name2) || -e $name2);    #skip collisions

  print "r: $name\n" if ($verbose > 2);
  rename($name, $name2);

  $name2;
}

sub pDir {
  my ($obj) = @_;
  return             if (!-d $obj);
  return             if (!opendir(DIR, $obj));

  print "p: $obj/\n" if ($verbose > 2);
  chdir($obj);

  foreach my $dir (readdir DIR) {
    next if ($dir =~ /^\.\.?$/);    #skip ./, ../
    pDir(clean($dir));
  }
  close(DIR);
  chdir("..");
}

sub main {
  foreach my $argv (@ARGV) {
    print "$argv/\n" if ($verbose > 3);
    $argv = clean($argv);
    if (-d $argv) { pDir($argv); }
  }
}

&main();

这些帖子是相关的，但并没有真正解决我的问题，

使用引号：How to handle filenames with spaces?（使用其他脚本，最好去掉引号）
File::Find perl script to recursively list all filename in directory（是的，但我还有其他原因）
网址转义：Modifying a Perl script which has an error handling spaces in files（不是网址）
引用元：How can I safely pass a filename with spaces to an external command in Perl?（不是网址）

【问题讨论】：

您不使用File::Find的“其他原因”是什么？它非常适合此目的，并且是核心模块，因此不需要安装。
从子程序中删除了前导 & 符号，使用了内置重命名

标签： perl recursion rename

【解决方案1】：

这是思考问题的另一种方式：

Perl 有一个内置的rename 函数。你应该使用它。
创建一个将旧名称映射到新名称的数据结构。拥有这些数据将允许进行各种健全性检查：例如，您不希望清理过的名称覆盖现有文件。
由于您没有递归处理目录，因此您可以使用glob 来获得优势。无需打开目录、读取目录、过滤掉点目录等麻烦。
不要调用带有前导＆符号的子例程（搜索此问题以获取更多详细信息）。
许多类 Unix 系统包含一个基于 Perl 的 rename 命令，用于快速而简单的重命名作业。即使您不将其用于当前项目，也很高兴知道。

这是一个粗略的大纲：

use strict;
use warnings;

sub main {
    # Map the input arguments to oldname-newname pairs.
    my @renamings = 
        map { [$_, cleaned($_)] }
        map { -f $_ ? $_ : glob("$_/*")  }
        @_;

    # Sanity checks first.
    #   - New names should be unique.
    #   - New should not already exist.
    #   - ...

    # Then rename.
    for my $rnm (@renamings){
        my ($old, $new) = @$rnm;
        rename($old, $new) unless $new eq $old;
    }
}

sub cleaned {
    # Allowed characters: word characters, hyphens, periods, slashes.
    # Adjust as needed.
    my $f = shift;
    $f =~ s/[^\w\-\.\/]/-/g;
    return $f;
}

main(@ARGV);

【讨论】：

非常好的代码。仍然：(1) 对rename 进行错误检查听起来是个好主意。 (2) 我很惊讶你有反斜杠但没有句点作为允许的字符：虽然 Windows 文件名永远不会包含反斜杠，但在 bash 中使用这个字符仍然非常不方便。

【解决方案2】：

不要将问题归咎于 Windows。 Linux 要宽松得多，它在文件名中唯一禁止的字符是 NUL。

不清楚你在问什么。您是否发布了代码以供批评，或者您有问题？

至于你问的具体问题，

除了空格、括号外还有哪些字符需要翻译？

Windows 允许在其文件名中使用任何字符，但从 0x00 到 0x1F 的控制字符和任何
```
 \ / * ? |
```
DEL 在 0x7F 很好。

在 ASCII 集合内，留下
！ # $ % & ' ( ) + , - . : ; =@[]^_`{}~
您需要翻译的字符集取决于您这样做的原因。您可能希望从排除非 ASCII 字符开始，因此您的代码应类似于

$name2 =~ tr/\x21-\x7E/-/c

这会将所有非 ASCII 字符、空格和 DEL 更改为连字符。然后你需要继续修复所有你认为undersirable的ASCII字符。
应该检查哪些其他文件属性（除了文件类型（文件/目录）和权限）？

这个问题的答案必须是根据你的目的。如果您只是指根据需要重命名文件或目录是否可能，那么我建议您让rename 自己告诉您它是否成功。如果操作失败会返回一个false值，原因在$!。
Perl 是否提供 pushd/popd 等价物，还是 chdir 是遍历目录树的合理解决方案？

如果您想使用该成语，那么您应该查看File::pushd，它可以让您暂时将chdir 转移到一个新位置。 popd 在封闭块的末尾隐式完成。

我希望这会有所帮助。如果您有任何其他具体问题，请通过编辑您的原始帖子提出。

【讨论】：