如何从 Tcl 执行 POSIX shell 转义

Question

有没有办法在 Tcl 中对字符串执行 POSIX shell 转义？

背景：

我有一个 Tcl 列表中的任意文件名列表。我需要扩展列表以粘贴到稍后将由任意 POSIX shell（bash、dash、posh 等）通过执行“sh -c”执行的 shell 片段中。

这是一个说明问题的例子：

#!/usr/bin/tclsh

set targets {with\ spaces has"stray'quotes has{brackets} $not_a_variable \[escaped_braces\] (not_a_subshell) weird\ \{|#^$(}

set shell_fragment {
  something
  some_command $targets
  something else
}

puts [subst $shell_fragment]

上面的输出是带有 Tcl 转义的名称：

  something
  some_command with\ spaces has"stray'quotes has{brackets} $not_a_variable \[escaped_braces\] (not_a_subshell) weird\ \{|#^$(
  something else

然而，我需要它看起来正常工作是这样的（POSIX shell 转义）：

  something
  some_command with\ spaces has\"stray\'quotes has{brackets} \$not_a_variable [escaped_braces] \(not_a_subshell\) weird\ {\|\#^\$\(
  something else

想法：

以下是我可以想象的一些我不想做的解决方法：

• 在 Bash 中，有一个用于 printf 的 %q 格式化程序，它可以满足我的需求。我可以为每个文件名执行一次 bash 调用以利用此功能，但这 1) 是一个很大的后盾，并且 2) 引入了对 bash 的依赖，我不希望这样做。

  李>

• 根据 POSIX shell 转义规则实现自己的 shell 转义。这显然可行，但我宁愿不重新发明轮子。我找到了一种“简单”的方法，通过发送垃圾引号来做到这一点，但这会使调试变得很糟糕，并大大减少了可用的命令行长度：

“坏”方法的示例：

proc posix_escape_via_bash {name} {
  return [exec bash -c {printf %q "$0"} $name]
}

proc posix_escape_via_spamming_quotes {name} {
  set escaped {}
  foreach char [split $name {}] {
    switch $char {
      '       {lappend escaped {\'}}
      default {lappend escaped '$char'}
    }
  }
  return [join $escaped {}]
}

再说一遍：有没有办法在 Tcl 中对字符串执行 POSIX shell 转义？如果有的话，我会很高兴有一种“标准”的方法，但我' d 也对非标准的 Tcl 库感到满意，甚至可以从 C 中做到这一点，所以我可以从 Tcl 中调用它。

Answer 1

这样做的关键是使用string map 或regsub。

使用string map转换一组字符

您所要做的就是为您想要转义的内容提供正确的映射。

对于您的特定情况，您似乎想要引用的唯一字符是'、"、$、(、)、<、> 和 | .让我们添加;、* 和?（我猜你不想要杂散的语句分隔符或通配符）。这很简单，但我们将迭代地生成映射，而不是使用文字：

set mappedChars {'"$()<>|&!;*?}    ;#'# Just to deal with SO's formatting...
set escaping {}
foreach c $mappedChars { lappend escaping $c "\\$c" }

这是您只需要做一次的事情。完成后，应用地图就很容易了：

set escapedTargets [string map $escaping $targets]

我会留给您找出将其与您使用 subst 合并的最佳方法。

使用regsub转换一组字符

另一种方法是将regsub 与-all 选项一起使用。只有在所有替代情况下都执行完全相同类型的转义时，这才真正有效。

# This puts a backslash in front of all non-alphanumerics
set escapedTargets [regsub -all {[^[:alnum:]]} $targets {\\&}]

# This _particular_ case has an almost-equivalent-good-enough that's shorter
set escapedTargets [regsub -all {\W} $targets {\\&}]

复杂之处在于为所有问题案例确定正确的表征正则表达式，这就是为什么经常说使用正则表达式将一个问题变成两个问题......

---

讨论/替代方法

上面的映射没有涵盖所有的 POSIX shell 元字符——特别是，它不处理反斜杠本身或空格（这样做会导致你的问题，因为你似乎想要获得多个单词），它也应该处理这些:{}[]~——正则表达式可能有点太敏锐了，在完全无辜的东西前面加上反斜杠。事实上，某些用途（例如，变量名）比上述任何一种方法都需要更多的注意，因为它们有一些根本无法使用的东西。

根本问题是shell实际上有一个非常复杂的语法，有很多交互规则。如果您可以编写代码而不需要运行 shell，那么您可能会发现事情更加可靠（以 Tcl 的 exec 和管道 open 的事实为模，它们有自己的奇怪问题，这些问题源于尝试太多像贝壳）。这是否适合您取决于您​​在问题中没有告诉我们的其他事情。

Answer 2

你可以'-引用所有非'字符一起而不是单独，你只需要结束和恢复'-quoting mid-string to \ - 转义任何' 字符。

所以你在'-quote 垃圾邮件中走在正确的轨道上，因为你已经意识到了

1. 单引号转义一切（除了'），这将特殊情况减少到只有一种，并且
2. 您可以在 shell 中连接带引号的字符串，并将它们解释为一个字符串（'a''b' 解析为与 'ab' 相同的原始字符串。

最后一个缺失的部分是第二点让我们优化了几乎所有的结尾并立即恢复'-quoting，这是在'-单独引用每个字符时发生的。

所以你需要的逻辑就是

1. 将所有' 替换为'\''，并且
2. 在开头和结尾放置一个'：

proc posix_escape_via_minimal_quotes {name} {
  set escaped {}
  lappend escaped '
  lappend escaped [string map {' '\\''} $name]
  lappend escaped '
  return [join $escaped {}]
}

示例输出：

% posix_escape_via_minimal_quotes x
'x'
% posix_escape_via_minimal_quotes xxx
'xxx'
% posix_escape_via_minimal_quotes xxx'xxx
'xxx'\''xxx'
% posix_escape_via_minimal_quotes '
''\'''

Answer 3

我最终做了一个我提到的“引用垃圾邮件”方法的变体，但是特殊的各种类型的字符要么永远不需要引用，要么可以用简单的反斜杠引用。这仍然有点过于急切，但比最初的幼稚方法要好得多。在大多数情况下，这与 bash printf 方法的结果相同。

  proc posix_escape {name} {
    foreach char [split $name {}] {
      switch -regexp $char {
        {'}           {append escaped \\'     }
        {[[:alnum:]]} {append escaped $char   }
        {[[:space:]]} {append escaped \\$char }
        {[[:punct:]]} {append escaped \\$char }
        default       {append escaped '$char' }
      }
    }
    return $escaped
  }

如果有更标准的方法可以做到这一点，我仍然非常感兴趣。如果以前没有人遇到过这种情况，我会感到非常惊讶！ =)