为什么 for /f 拉起文件名？

Question

我有一个名为paths.txt的文本文件，它包含以下数据，

本地名称远程路径
N：\DANIEL-HP\Users\Public
Z：\DANIEL-HP\Users\Public\Favorites
本地名称远程路径
N：\DANIEL-HP\Users\Public
Z：\DANIEL-HP\Users\Public\Favorites

我正在运行以下批处理文件来提取所需的信息路径字母 path。

@echo off
for /f "tokens=1 delims=" %%a in ('find ":" paths.txt') do (
echo %%a
)
pause

结果

---------- PATHS.TXT
N:         \\DANIEL-HP\Users\Public
Z:         \\DANIEL-HP\Users\Public\Favorites
N:         \\DANIEL-HP\Users\Public
Z:         \\DANIEL-HP\Users\Public\Favorites
Press any key to continue . . .

我解决这个问题的方法是修改 FOR 如下，

for /f "skip=2 tokens=1 delims=" %%a in ('find ":" paths.txt') do (echo %%a)

我得到了一个干净的期望输出，

N:         \\DANIEL-HP\Users\Public
Z:         \\DANIEL-HP\Users\Public\Favorites
N:         \\DANIEL-HP\Users\Public
Z:         \\DANIEL-HP\Users\Public\Favorites
Press any key to continue . . .

问题是，我的第一个 FOR 函数有什么问题，它允许文件名通过。

Answer 1

问题在于您的 FIND 命令，而不是您的 FOR /F。

如果 FIND 打开文件本身（如果文件名作为参数传入），它总是会打印出文件名。

您可以通过使用重定向来避免文件名：

find ":" <paths.txt

或管道：

type paths.txt | find ":"

要在 FOR 循环中使用这些，必须对管道或重定向进行转义。

for /f "tokens=1 delims=" %%a in ('find ":" ^< paths.txt') do echo %%a
for /f "tokens=1 delims=" %%a in ('type paths.txt ^| find ":"') do echo %%a

另一种替代方法是使用 FINDSTR（但仅当文件为 ASCII 时）：

findstr ":" paths.txt

如果文件是 unicode (UTF-16)，那么您可以通过管道 TYPE 命令的输出将内容转换为 ASCII（同样，如果在 FOR /F 中使用管道，则转义管道）：

type paths.txt | findstr ":"

Answer 2

需要删除;))

/* 我的建议：

find ":" ^<paths.txt
type paths.txt ^| find ":"

findstr 工作得很好.. 我不明白你有什么空白

@echo off
set "tmp=PATHS.TXT"----your value
echo,---findstr
for /f "tokens=1 delims=" %%a in ('findstr ":" %tmp%') do (echo %%a)
echo,---type
for /f "tokens=1 delims=" %%a in ('type %tmp% ^| find ":"') do (echo %%a)
echo,---redirect
for /f "tokens=1 delims=" %%a in ('find ":" ^<%tmp%') do (echo %%a)

*/