在 GraphDB 的 Lucene 连接器中使用通配符

Question

我正在使用 GraphDB 的 Lucene connectors。我为我的三重存储中的实体代码构建索引my_index，我想使用这样的索引进行子字符串匹配。

示例。

实体代码：

FooBar
FooBaz
BazFoo

Lucene 连接器：

PREFIX :<http://www.ontotext.com/connectors/lucene#>
PREFIX inst:<http://www.ontotext.com/connectors/lucene/instance#>
INSERT DATA {
    inst:my_index :createConnector '''
{
  "fields": [
    {
      "fieldName": "code",
      "propertyChain": [
        "http://foo#identifier"
      ],
      "indexed": true,
      "stored": true,
      "analyzed": true,
      "multivalued": true,
      "facet": true
    }
  ],
  "types": [
    http://foo#MyType"
  ],
  "stripMarkup": false
}
''' .
}

SPARQL 查询利用 Lucene 连接器：

PREFIX : <http://www.ontotext.com/connectors/lucene#>
PREFIX inst: <http://www.ontotext.com/connectors/lucene/instance#>

SELECT ?entity {
  ?search a inst:my_index ;
      :query "code:Foo*" ;
      :entities ?entity .
}

我想获取代码以Foo 开头的所有实体（即FooBar、FooBaz），但我得到的是一个空结果集。

我怎样才能得到它们？

编辑：

在尝试了 Vassil 的answer 中的示例后，我发现问题可能与区分大小写有关。

行为：

• :query "label:Foo*" 不返回任何内容

• :query "label:foo*" 返回FooBar 和FooBaz

Answer 1

默认情况下，前缀搜索应该是开箱即用的。我怀疑您的查询还有另一个问题。如果你用:query "*:*" 搜索所有可能的值会发生什么？

这是一个测试用例，用于检查并使用您的数据集重复它。

生成样本虚拟数据

PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>
INSERT DATA
{
    <urn:1> a <urn:type>;
        rdfs:label "FooBar".
    <urn:2> a <urn:type>;
        rdfs:label "FooBaz".
    <urn:3> a <urn:type>;
        rdfs:label "BazFoo".
}

您还需要为每个 RDF 资源定义 rdf:type 语句。

创建 Lucene 连接器

PREFIX :<http://www.ontotext.com/connectors/lucene#>
PREFIX inst:<http://www.ontotext.com/connectors/lucene/instance#>
INSERT DATA {
    inst:my_index :createConnector '''
{
  "fields": [
    {
      "fieldName": "label",
      "propertyChain": [
        "http://www.w3.org/2000/01/rdf-schema#label"
      ],
      "indexed": true,
      "stored": true,
      "analyzed": true,
      "multivalued": true,
      "facet": true
    }
  ],
  "types": [
    "urn:type"
  ],
  "stripMarkup": false
}
''' .
}

连接器将索引所有urn:type 类的所有rdfs:label 值。

测试前缀搜索

PREFIX : <http://www.ontotext.com/connectors/lucene#>
PREFIX inst: <http://www.ontotext.com/connectors/lucene/instance#>

SELECT ?entity {
  ?search a inst:my_index ;
      :query "label:Foo*" ;
      :entities ?entity .
}

数据库返回urn:1和urn:2