如何从 Azure AppInsights 分析访问自定义事件值？

Question

我正在向 Azure 报告一些自定义事件，自定义事件中有一个值保存在名为“totalTime”的 customMeasurements 对象下。

事件本身如下所示：

loading-time: {
    customMeasurements : { 
        totalTime: 123
    }
}

我正在尝试创建一个图表，显示每小时报告给 azure 的所有事件的平均总时间。所以我需要能够收集和平均事件中的值。

我似乎不知道如何从 Azure AppInsights Analytics 中访问 c​​ustomMeasurements 值。这是 Azure 提供的一些代码。

union customEvents
| where timestamp between(datetime("2019-11-10T16:00:00.000Z")..datetime("2019-11-11T16:00:00.000Z"))
| where name == "loading-time"
| summarize Ocurrences=count() by bin(timestamp, 1h)
| order by timestamp asc
| render barchart

此代码仅计算过去 24 小时内报告的事件数并按小时显示。

我已尝试通过执行访问事件中保存的 customMeasurements 对象

summarize Occurrences=avg(customMeasurements["totalTime"])

但 Azure 不喜欢这样，所以我做错了。如何访问我需要的值？我似乎也找不到任何文档。

Answer 1

将来自 customDimensions / customMeasurements 属性集合的数据投影到一个新变量中会很有用，您将使用该变量进行进一步聚合。您通常需要使用 todecimal、toint、tostring 函数之一将维度数据转换为预期类型。

例如，我对依赖遥测有一些额外的测量，所以我可以这样做

dependencies
| project ["ResponseCompletionTime"] = todecimal(customMeasurements.ResponseToCompletion), timestamp 
| summarize avg(ResponseCompletionTime) by bin(timestamp, 1h) 

您的查询可能类似于，

customEvents
| where timestamp between(datetime("2019-11-10T16:00:00.000Z")..datetime("2019-11-11T16:00:00.000Z"))
| where name == "loading-time"
| project ["TotalTime"] = toint(customMeasurements.totalTime), timestamp 
| summarize avg(TotalTime) by bin(timestamp, 1h)
| render barchart