在 groovy 中动态执行代码

Question

我正在尝试在 groovy 中动态运行代码。我有someNode[0]，这是变量var1中的值

然后我像这样添加双引号

var2 = "\""+var1+"\""

然后我尝试运行它

request.abc."$var2"=Value

我看到here 可以在属性和方法上执行此类操作。但是上面的代码不起作用。给我错误

An error occurred [Cannot set property '"someNode[0]"' on null object], see error log for details

感谢任何帮助。谢谢。

编辑 这是我的请求的sn-p

{
   "app":{
      "bundle":"531323947",
      "cat":[
         "IAB1",
         "IAB9",
         "IAB9-30",
         "entertainment",
         "games"
      ],
      "id":"agltb3B1Yi1pbmNyDAsSA0FwcBitsL4UDA",
      .
      .

我要操作的字段是cat[0]，即IAB1（我只是在上面写的代码中使用了abc 和someNode[0]，但实际上它们是app 和cat[0]）

另外，在运行上述代码之前，我使用jsonslurper 解析了请求

感谢您的帮助

Answer 1

一种方法是通过Eval

def request =[
"app":[
    "bundle":"531323947",
    "cat":[
            "IAB1",
            "IAB9",
            "IAB9-30",
            "entertainment",
            "games"
    ],
]
]

assert request.app.cat[0]=='IAB1'
def var = 'request.app.cat[0]'
Eval.me('request', request, "$var = 'new value'")
assert request.app.cat[0]=='new value'

Answer 2

您正在访问/更新地图和列表中的值。 request.app 节点将是一个地图，request.app.cat 节点将是一个列表。可以通过多种不同的方式获取和设置地图中的值：

1. 直接使用put & get 方法。
2. 使用括号[]。
3. 使用缺少的属性作为映射键（即您使用它的方式）。

对于您想要实现的目标，即从变量键访问值，使用方法 1 或 2 比方法 3 更容易，而方法 3 在 GString 中带有变量。

使用括号的示例：

import groovy.json.JsonBuilder
import groovy.json.JsonSlurper

def request = new JsonSlurper().parseText '''{
        "app":{
            "bundle":"531323947",
            "cat":[
                "IAB1",
                "IAB9",
                "IAB9-30",
                "entertainment",
                "games"
            ],
            "id":"agltb3B1Yi1pbmNyDAsSA0FwcBitsL4UDA"
        }
    }'''

def level0 = 'app'
def level1 = 'cat'

def node = request[level0][level1]

assert request instanceof Map
assert node instanceof List
assert node[0] == 'IAB1'

node[0] = 'new value'
assert node[0] == 'new value'

println new JsonBuilder(request).toPrettyString()

输出：

{
    "app": {
        "cat": [
            "new value",
            "IAB9",
            "IAB9-30",
            "entertainment",
            "games"
        ],
        "id": "agltb3B1Yi1pbmNyDAsSA0FwcBitsL4UDA",
        "bundle": "531323947"
    }
}