如何在 Gnuplot 中创建类似箭头线的流线型？

Question

我想在 Gnuplot 中创建一个类似箭头线的流线，我已经有了我需要的数据点，所以我认为我的问题与this post 所说的不同，也与this post 不同，因为我已经获得stramlines 所需的数据。

我的做法是这样的：

所以红线是矢量显示流场，绿线是流线，引导读者了解通量的方向。所有的蓝色大箭头都是我在 GNUPLOT 中绘制的目标。正如this post 所示，我知道如何绘制中间箭头，但是如果我想沿着线条绘制更多箭头，我需要做什么代码？

更详细地说，我怎样才能像这样绘制：

我在这里提供我的数据文件：

velocity.txt 用于矢量流场数据为“index,X,Y,vx,vy,particle-numbers”

line.txt 用于将数据流线化为“X,Y”

而我的 gnu 文件已损坏：

set terminal postscript eps size 108,16 enhanced font "Arial-Bold,100"
set output 'vector.eps'

unset key
set tics
set colorbox
set border 0
set xtics 2
#set xlabel 'x'
#set ylabel 'y'


set xrange [0:108]
set yrange [0:16]
#set cbrange [0:40]

set nolabel
set style line 4 lt 2 lc rgb "green" lw 2

plot 'velcoity.txt' u 2:3:(250*$4):(250*$5) with vectors lc 1,'line.txt' u 1:2 ls 4

谢谢！

Answer 1

要沿线绘制箭头，您可以再次使用vectors 绘图样式，就像您已经为流场所做的那样。

但要获得正确的情节，您必须考虑以下几点：

1. 通常 gnuplot 将箭头的大小限制为箭头长度的一小部分。所以，如果你想用箭头绘制一条连续的线，箭头本身应该有很短的长度。为避免箭头缩小，请使用 size ... fixed 选项，该选项仅从 5.0 版开始提供

2. 您只有直线的轨迹，x 和 y 值。要提取箭头方向，最简单的方法是使用两个相邻点（或两三个点的距离）之间的差异。

3. 您可以在using 语句中提取这些差异。作为伪代码，可以执行以下操作：

   if rownumber modulo 10 == 0:
       save x and y values
   else if rownumber modulo 10 == 1:
       draw arrow from previous point to current point, only with a head
   else 
       ignore the point.
   

   将此伪代码放在using 语句中会得到以下结果：

   ev = 10
   avg = 1
   sc = 0.1
   plot 'line.txt' u (prev_x = (int($0)%ev == 0 ? $1 : prev_x), prev_y = (int($0)%ev == 0 ? $2 : prev_y), int($0)%ev == avg ? $1 : 1/0):2:(sc*(prev_x-$1)):(sc*(prev_y-$2)) w vectors backhead size 2,20,90 fixed ls 4
   

   为了让事情更灵活，我引入了一些变量：ev告诉你两个箭头之间的差异计数，avg用于计算箭头方向的两点之间的距离，以及sc的长度箭头轴。

作为进一步的改进，您可以使用流场箭头的长度来为流场矢量着色。这给出了以下脚本

reset
unset key
set tics
set colorbox
set border 0
set xtics 2

set autoscale xfix
set autoscale yfix
set autoscale cbfix
set style line 4 lt 2 lc rgb "green" lw 2
ev=30
avg=3
sc=0.1
field_scale=500
plot 'velcoity.txt' u 2:3:(field_scale*$4):(field_scale*$5):(sqrt($4**2+$5**2)) with vectors size 1,15,45 noborder lc palette,\
     'line.txt' u 1:2 ls 4 w l,\
     '' u (prev_x = (int($0)%ev == 0 ? $1 : prev_x), prev_y = (int($0)%ev == 0 ? $2 : prev_y), int($0)%ev == avg ? $1 : 1/0):2:(sc*(prev_x-$1)):(sc*(prev_y-$2)) w vectors backhead size 2,20,90 fixed ls 4

结果（qt终端）：