Gnuplot 没有在所有的 tic 标记上贴上标签

Question

我正在做一个短数据文件的日志图：

22.5 4.5
15.5 7.4
12.2 9.6
8.0 12.5
7.1 14
5.7 16.4
4.4 18.2
3.8 20.8
3.2 23.5
1.2 28.3
0.2 38.4

目前我使用的命令如下：

plot "data.dat" using (($2)*0.01):(($1)*(10**(-5))):(0.005):(0.3*(10**(-5))) with xyerrorbars linestyle 7 title 'dados colhidos'
set logscale
set xrange [0.035:0.4]
set yrange [0.05*(10**(-5)):30*(10**(-5))]
set xtics 0.04,0.05,0.39
set ytics 0.1*(10**(-5)),5*(10**(-5)),30*(10**(-5))
set xtics nomirror
set ytics nomirror
set format x "%f"
set format y "%f"
replot

但在图中只有第一个 tic 标记（x 和 y 轴）被标记：

x 轴为 0.04，y 轴为 0.1*(10**(-5))。

如果我有足够的声誉，我会发布我得到的情节图片......

我已经在一些关于 gnuplot 的书籍和互联网上进行了搜索，但没有找到任何帮助。

我想要的是所有标记处的标签（数字）。你有什么想法吗？

感谢阅读！

我使用的是版本 4.6 补丁级别 5。

Answer 1

对于对数图，set xtics 和 set ytics 指定的增量是乘数。此外，对于对数图，您不能使用任意 tic 标签，但标签必须与用于对数刻度的基数相关。

考虑这个例子

set logscale
set xrange [0.035:0.4]
set yrange [0.05*(10**(-5)):30*(10**(-5))]
set tics format "%f"
unset key

plot "data.dat" using ($2 *0.01):($1*1e-5):(0.005):(0.3e-5) with xyerrorbars ls 7

结果

这对我来说在 y 轴上看起来不错。对于 x 轴，您可能想尝试使用不同的对数刻度基数。但如果结果更好，你必须自己决定：

set logscale y
set logscale x 2
set mxtics 8
set xrange [0.035:0.4]
set yrange [0.05*(10**(-5)):30*(10**(-5))]
set tics nomirror format "%f"
unset key

plot "data.dat" using ($2 *0.01):($1*1e-5):(0.005):(0.3e-5) with xyerrorbars ls 7