IF EXIST - 匹配大小写的批处理脚本

Question

我的要求是仅在大小写匹配搜索时检查文件是否存在于文件夹中。

我已经搜索了互联网，还有基本的命令提示符帮助指南。我没有准确的答案。但是，在 StackOverflow 帖子中：REF-Post 通过将 FileName 作为变量发送到批处理文件来提供解决方案。但是，我想通过不使用发送到批处理文件的任何变量来搜索文件。

@echo off 
dir /b /a-d "%~1"|find "%~1" >nul
if %errorlevel% == 0 (echo found) else (echo fail)

此代码采用 %~1 值，我想直接用路径替换 %~1！请帮忙解决

例如： 文件夹 C:\Files\ 中存在一个名为 testfile.txt 的文件 逻辑应该是这样的：

IF EXIST C:\Files\TESTFILE.txt (
  echo file of case exists
) else (
  echo file of this case does not exist
)

Answer 1

这是 Gerhard 使用 FINDSTR 的原始答案的更正形式：

dir "C:\files" /b /a-d | findstr /x /c:"TESTFILE.txt" && echo Found || echo Not found

需要/c:"string" 选项来强制进行文字解释（不是正则表达式），并允许名称中包含空格。需要/X 选项来强制完全匹配。您不想误匹配“the_TESTFILE.txt”。

以上可能是最直接的技术。

这也可以通过 FOR 语句来解决。如果%%F 包含现有文件的名称（不区分大小写），则%%~nxF 将扩展为磁盘上实际区分大小写的名称。
但是如果%%F 不存在，那么%%~nxF 将永远不会改变大小写。所以IF EXIST也必须使用。

必须仔细构造命令才能给出正确的结果。我的目标是拥有一个自包含结构，允许在最后使用&& 和||，根据文件是否存在有条件地采取行动。

pushd C:\files
(
  for %%F in ("TESTFILE.txt") do (
    if exist %%F if %%~F==%%~nxF popd & (call)
  ) && popd
) && echo NOT FOUND || echo FOUND

或单行

pushd C:\files&(for %%F in ("TESTFILE.txt") do (if exist %%F if %%~F==%%~nxF popd&(call))&&popd) && echo NOT FOUND || echo FOUND

注意逆逻辑。如果文件存在且大小写匹配，则 (call) 是括号内最后执行的命令，导致返回码非零。如果文件不存在或大小写不匹配，则popd 是括号内最后执行的命令，导致返回码为零。

Answer 2

使用首选大小写搜索文件：

@echo off
set "res=" && for /f "delims=" %%i in ('dir "C:\Files" /b /a-d') do if "%%i"=="TESTFILE.txt" set "res=%%i"
if defined res (echo %res% Found) else (echo File not found)

仍在使用for /f，但没有设置变量：

@echo off
for /f "delims=" %%i in ('dir "C:\files" /b /a-d') do if "%%i"=="TESTFILE.txt" echo File found & goto :eof
echo File not found

或者只是没有/f，但你需要

@echo off
for %%i in (C:\Files\*) do if "%%i"=="TESTFILE.txt" echo File found & goto :eof
echo File not found