如何在断言失败时使非交互式 Maple 退出？

Question

我的t.ms 文件包含：

interface(prettyprint=0): kernelopts(assertlevel=1):
ASSERT(1<1):
ASSERT(2<2):

当我跑步时：

maple -q t.ms; echo $?

我明白了：

Error, assertion failed
Error, assertion failed
0

当我跑步时：

maple -e 2 -q t.ms; echo $?

我明白了：

Error, assertion failed
0

我想得到：

Error, assertion failed
4

也就是说，我希望 Maple 在第一个失败的断言时以非零退出状态退出。 （我不在乎退出代码是 1 还是其他任何值，只要它不为零即可。我从 documentation 得到数字 4，与 errorbreak 相关）我如何得到它?

Answer 1

文档并没有明确说明必须使用，

`quit`(n)

带有名称引号。

interface(prettyprint=0):

handler:=proc(e::uneval)
  local failed;
  printf("entered\n"); # remove this when satisfied
  failed:=false;
  try
    if evalb(eval(e)) <> true then
      error;
    end if;;
  catch:
    failed:=true;
    printf("Error, assertion failed\n");
  finally;
    if failed then
       `quit`(5);
    end if;
  end try;
  true;
end proc:

ASSERT( handler( 1<1 )):
ASSERT( handler( 2<2 )):

现在，将其保存为文件 uh.mpl，然后使用 Maple 18.01 for Linux，我看到了，

$ maple18.01 -q -A 2 ~/uh.mpl ; echo $?
entered
Error, assertion failed
5

如果在没有 -A 2 的情况下运行，则不会运行断言检查。

[已编辑] 下面是一个轻微的修改，用于处理附加参数作为打印的一部分。

handler:=proc(e::uneval)
  local failed;
  printf("entered\n"); # remove this when satisfied
  failed:=false;
  try
    if evalb(eval(e)) <> true then
      error;
    end if;;
  catch:
  failed:=true;
  printf("Error, assertion failed, %q\n", _rest);
  finally;
  if failed then
     `quit`(5);
  end if;
  end try;
  true;
end proc: