Excel：Sumifs 公式，可能有索引匹配？

Question

我正在尝试创建一个 SUMIFS，它可以检查数据范围内的“子”行，然后使用“父”ID 号（列在子行中）检查父数据和总和。我在下面插入了一张表格的图片，它给出了一个虚拟数据集。这种公式的预期结果是：

第 1 阶段有父母的孩子：$0

第 2 阶段有父母的孩子：80 美元

第 3 阶段有父母的孩子：10 美元

提前感谢您的帮助！

Example Data Set

或者作为文本：

ID  Type    Parent ID   Phase   Finances
1   Single              1       $10
2   Parent              2       $10
3   Child   2                   $10
4   Single              3       $10
5   Parent              3       $10
6   Child   5                   $10
7   Single              1       $10
8   Parent              2       $10
9   Child   8                   $10
10  Child   8                   $10
11  Child   8                   $10
12  Child   8                   $10
13  Child   8                   $10
14  Child   8                   $10
15  Child   8                   $10

Answer 1

假设您的桌子在 A1 到 E16 之间。

生成填充空白阶段的辅助列。假设空白阶段与父 ID 具有相同的阶段，则将填充空白阶段。因此在 F1 中放置以下公式并向下复制到 F16：

=IF(D2<>"",D2,VLOOKUP(C2,$A$2:$D$16,4,0))

现在我们可以使用 sumproduct 并获取独生子女和第 2 阶段的总数。在 H1 到 J3 中，我构建了您要查找的内容的汇总表。在 H1 到 J1 中，我使用了标题，在 H2 到 I 4 中，我定义了我要搜索的内容。在 J2 到 J4 中，我使用了以下公式来确定财务状况：

Type   |  Phase  |  Finance
Child  |    1    |  =SUMPRODUCT(($B$2:$B$16=H2)*($F$2:$F$16=I2)*$E$2:$E$16)
Child  |    2    |  =SUMPRODUCT(($B$2:$B$16=H3)*($F$2:$F$16=I3)*$E$2:$E$16) 
Child  |    3    |  =SUMPRODUCT(($B$2:$B$16=H4)*($F$2:$F$16=I4)*$E$2:$E$16)

sumproduct 仅对表中存在 CHILD（如 H 列中定义）和 phase 等于 I 中定义的数字的行求和，并且仅对财务列中对应的值求和。如果 B 中不存在子元素，或者 F 中的相位不等于正在搜索的数字，则该行的值为 0。

概念证明

Answer 2

这是一个数组公式：

=SUM(IF($C$2:$C$16<>"",(LOOKUP($C$2:$C$16,$A$2:$A$16,$D$2:$D$16)=G2)*$E$2:$E$16))

作为数组公式，离开编辑模式时需要使用 Ctrl-Shift-Enter 确认。如果操作正确，Excel 会在公式周围加上{}。