如何将索引功能与多个条件结合起来？答案

【问题标题】：How to combine the index function with multiple criteria?如何将索引功能与多个条件结合起来？
【发布时间】：2019-08-29 21:20:18
【问题描述】：

我无法确定索引函数。我的数据表如下

表 1 - 所有控股公司持有的所有子公司的完整列表 - 第一栏显示控股公司 - 第二栏显示各控股公司持有的子公司 - 第三、第四和第五列给出了这些子公司的主要财务状况（EBITDA）

标签 1 之后的标签是每个控股公司的标签。在这些选项卡中，我有一个部分，我只想包含选项卡 1 中 EBITDA 高于 2000 万的子公司

示例：控股公司A有以下子公司：Sub1 (EBITDA:10m), Sub2 (EBITDA: 21m), Sub3 (EBITDA: 15m)。

在 A 公司的选项卡中，我只想显示 Sub2 的信息，因为它符合最低阈值

我现在拥有的功能显示每个控股公司的每个子公司的所有信息，无论其 EBITDA 是多少：

=IFERROR(INDEX(Tab1!D$5:D$337,SMALL(IF(Tab1!$C$5:$C$337=$C$6,ROW(Tab1!D$5:D$337)-MIN(ROW(Tab1!D$5:D$337))+1),ROWS(B$55:B55))),"")

Tab1 D 列包含所有子公司名称 Tab1 C 列包含所有控股公司名称 B 列是我在控股公司选项卡中插入子公司的位置

输出提供每个控股的所有子公司，但我只希望每个控股的子公司的 EBITDA 等于或大于 20m

如果每个子公司的 3 年 EBITDA（Tab1 列 N、O 和 P）中的一个或多个等于或大于 20m，我如何添加一个条件进行过滤？

非常感谢！

【问题讨论】：

标签： excel indexing match

【解决方案1】：

将 IF 语句中的条件从：

Tab1!$C$5:$C$337=$C$6

同时检查 N、O 或 P 列是否超过 20m：

(Tab1!$C$5:$C$337=$C$6)*((Tab1!$N$5:$N$337>20000000)+(Tab1!$O$5:$O$337>20000000)+(Tab1!$P$5:$P$337>20000000))

【讨论】：

最后一个范围应该是 (Tab1!$P$5:$P$337>20000000) 而不是 (Tab1!$O$5:$O$337>20000000))
发现良好，已修复。

【解决方案2】：

您使用的是FormulaArray，但是，您也可以使用这个标准公式（在B6 输入）：

= IFERROR( INDEX( 'Tab1'!$D$5:$D$337,
AGGREGATE( 15, 6, ROW(B:B) /
( ( 'Tab1'!$C$5:$C$337 = $C$6 ) *
( ( 'Tab1'!$N$5:$N$337 > 20 ) + ( 'Tab1'!$O$5:$O$337 > 20 ) + ( 'Tab1'!$P$5:$P$337 > 20 ) <> 0 ) ),
ROWS( B$5:B5 ) ) ), "" )

【讨论】：