通过公式 (Excel) 更改较大单元格区域中的单元格时的时间戳

Question

作为this 问题的后续行动，每当通过一系列单元格的公式更改单元格时，我都需要在相邻单元格中设置时间戳。

我知道这意味着构建一个数组以将先前的值存储到下面的代码中（实现相同但仅适用于单个单元格）并且希望能帮助实现这一点。

这是适用于单个单元格的代码...

在Sheet1单元格A1中，输入这个公式

=Sheet2!A1+1

现在在一个模块中粘贴这段代码

Public PrevVal As Variant

将此粘贴​​到工作表代码区域

Private Sub Worksheet_Calculate()
    If Range("A1").Value <> PrevVal Then
        Range("B1").Value = Format(Now, "dd/mm/yyyy hh:mm:ss")
        PrevVal = Range("A1").Value
    End If
End Sub

最后在 ThisWorkbook 代码区域粘贴此代码

Private Sub Workbook_Open()
    PrevVal = Sheet1.Range("A1").Value
End Sub 

Answer 1

您可以将以前的值保存在 Dictionary 而不是数组中。要使用字典，您需要添加对 Microsoft Scripting Runtime Library

的引用

（工具 > 参考 > Microsoft 脚本运行时库）

---

标准模块

Public PrevVal As Dictionary

---

ThisWorkbook 模块

Private Sub Workbook_Open()
    Dim r As Range
    Set PrevVal = New Dictionary
    For Each r In Worksheets("Sheet1").Range("A1:A10")
        PrevVal.Add Item:=r.Value, Key:=r.Address
    Next r
End Sub

---

表格模块

Private Sub Worksheet_Calculate()
    Dim v As Variant

    For Each v In PrevVal.Keys()
        If Range(v).Value <> PrevVal(v) Then
            Range(v).Offset(0, 1).Value = Format(Now, "dd/mm/yyyy hh:mm:ss")
            PrevVal(v) = Range(v).Value
        End If
    Next v
End Sub