什么是协变函子？

Question

我想明白，为什么例如Maybe 类型是协变函子？

协变是什么意思？

请举例说明。

Answer 1

协变函子只是普通的Functor类：

class Functor f where
    fmap :: (a -> b) -> f a -> f b

例如，Maybe（如您所述）：

instance Functor Maybe where
    fmap _ Nothing = Nothing
    fmap f (Just a) = Just (f a)

但是，还有另一种类型的函子：逆变函子。这些定义如下：

class Contravariant f where
    contramap :: (a -> b) -> f b -> f a

请注意，与fmap相比，contramap颠倒了b和a的顺序：

fmap      ::       Functor f => (a -> b) -> f a -> f b
contramap :: Contravariant f => (a -> b) -> f b -> f a
                                         --   ^      ^
                                         --   look!

现在，这个疯狂的Contravariant 类是否有任何实例？嗯，是。例如，这是Predicate的定义：

newtype Predicate x = Predicate { decide :: x -> Bool }

换句话说，Predicate x 是一个计算x 条件的函数。我们可以将contramap 专门化为Predicates：

contramap :: (a -> b) -> Predicate b -> Predicate a

相当于：

contramap :: (a -> b) -> (b -> Bool) -> (a -> Bool)

基本上，给定bs 上的Predicate，以及从as 到 bs 的映射，您可以通过contramap 在@ 上获得Predicate 987654346@s。 （我将把实现留作练习。）这是一个示例（未经测试）：

hasMultChars :: Predicate String
hasMultChars = Predicate $ \x -> length x > 1

showInt :: Int -> String
showInt = show

intHasMultChars :: Predicate Int
intHasMultChars = contramap showInt hasMultChars

事实证明，与普通协变函子相比，逆变函子要少得多，所以用处也少得多。所以在实践中，我们省略了“协变”，因为在大多数情况下它不会添加任何东西。

Answer 2

协变函子是“内”和“外”箭头指向同一方向的函子。

class Functor f where
  fmap :: (a -> b) -> (f a -> f b)

逆变函子是“内部”和“外部”箭头指向相反方向的函子。

class Contravariant f where
  contramap :: (a -> b) -> (f a <- f b)

...或者，使用正确的 Haskell 语法，

  contramap :: (a -> b) -> (f b -> f a)

这通常表明参数类型作为数据类型中的函数参数出现在某处，例如

data DepInt x = DepInt (x -> Int)

instance Contravariant DepInt where
  contramap f (DepInt g) = DepInt $ g . f

相反，如果参数仅按原样出现或出现在函数箭头的右侧，则它是协变函子。大多数函子都是这种情况，这就是为什么这个类被简单地称为Functor。