使用 ArrayFormula 扩展 Countifs 的行和列答案

【问题标题】：Using an ArrayFormula to expand Countifs both rows and columns使用 ArrayFormula 扩展 Countifs 的行和列
【发布时间】：2019-12-12 20:23:10
【问题描述】：

问题：我正在尝试制作一个动态数组公式计数，它将自动扩展新的行和列。条件行和标题由唯一公式自动填充。

到目前为止我所拥有的：
标题来自 G3:3（将使用新数据扩展各个列）
标准行从 A4:A 开始并从那里向下（将使用新数据扩展各种行）
当前工作公式
={ArrayFormula(COUNTIFS('True Rejections (Do Not Modify)'!$B$3:$B,INDIRECT("$A4:$A" & 'Settings (Do Not Modify)'!$B$1+3),'True Rejections (Do Not Modify)'!$C$3:$C,G$3)); ""; SUM(ArrayFormula(COUNTIFS('True Rejections (Do Not Modify)'!$B$3:$B,INDIRECT("$A4:$A" & 'Settings (Do Not Modify)'!$B$1+3),'True Rejections (Do Not Modify)'!$C$3:$C,G$3)))}
这个公式的问题是我必须将其复制并粘贴到标题（第 4 行）下的每个单元格中以使其计数。

我尝试将 G$3 修改为 G$3:3，但我收到一个错误，即 COUNTIFS 的数组参数大小不同。下图是截图，抱歉不能分享live sheet。

想将公式放在 YTD Tracker 表的红色单元格中
https://docs.google.com/spreadsheets/d/1Zdm8s-qby7SPRYelLAHmhN46uMROGKhRw8GtfI5nOYg/edit?usp=sharing

【问题讨论】：

我尝试使用如下 sumproduct 并遇到类似的问题，如 countifs =ArrayFormula(SUMPRODUCT(('True Rejections (Do Not Modify)'!$B$3:$B = A4:A12)*('True Rejections (Do Not Modify)'!$C$3:$C = G3:M3))) 错误：EQ 的数组参数大小不同
与一些虚假数据分享您的工作表副本
@player0 我在原帖中分享了一张表格
我看了你的床单，不知道你在追求什么。它看起来与图片不同，它有一些 REF 错误，并且样本不是很容易自我解释。能详细解释一下吗？
@player0 忽略 B-F 列，这些列在工作电子表格上运行良好。 True Rejections 上的数据是从另一个电子表格（我无权访问）导入的，并且每月更新一次。通过这些每月更新，新用户可能会添加新问题。我的目标是拥有一个可以向下和向右扩展的计数。希望对您有所帮助。

标签： google-sheets google-sheets-formula array-formulas google-sheets-query gs-vlookup

【解决方案1】：

尝试：

=ARRAYFORMULA(IFNA(VLOOKUP(INDIRECT("A4:A"&COUNTA(A4:A)+2), 
 QUERY(QUERY('True Rejections (Do Not Modify)'!A3:C, 
 "select B,count(B) where B is not null group by B pivot C"), "offset 1", 0), 
 TRANSPOSE(ROW(INDIRECT("A2:A"&
 COUNTUNIQUE('True Rejections (Do Not Modify)'!C3:C)+1))), 0))*1)

没有零：

=ARRAYFORMULA(IFNA(VLOOKUP(INDIRECT("A4:A"&COUNTA(A4:A)+2), 
 QUERY(QUERY('True Rejections (Do Not Modify)'!A3:C, 
 "select B,count(B) where B is not null group by B pivot C"), "offset 1", 0), 
 TRANSPOSE(ROW(INDIRECT("A2:A"&
 COUNTUNIQUE('True Rejections (Do Not Modify)'!C3:C)+1))), 0)))

【讨论】：

我查看了您添加到工作表中的两个公式，它们都是我正在寻找的。我最终选择了没有零的那个。您能否修改您的答案以包含两个公式，以防其他人需要相同的东西。谢谢。