对列表中的项目使用过滤器？

Question

我正在尝试按列表中的项目过滤并逐行打印它们。这是我的代码：

data Car = Car String [String] Int [String]

testDatabase :: [Car]
testDatabase = [Car"Casino Royale" ["Daniel Craig"] 2006 ["Garry", "Dave", "Zoe", "Kevin", "Emma"],Car"Blade Runner" ["Harrison Ford", "Rutger Hauer"] 1982 ["Dave", "Zoe", "Amy", "Bill", "Ian", "Kevin", "Emma", "Sam", "Megan"]]



formatCarRow (Car a b c d) =  show a ++ " | " ++ concat [i ++ ", " | i <- init b] ++ last b ++ " | " ++ show c ++ " | " ++ concat [j ++ ", " | j <- init d] ++ last d



displayFilmsByYear :: String -> IO [()]
displayFilmsByYear chosenYear = mapM (putStrLn.formatFilmRow) [putStrLn(filter ((== chosenYear).y)) |  (w x y z) <- testDatabase] -- This is the code not working i think

为什么这不起作用？

Answer 1

如果你想过滤一个列表，我推荐使用filter 函数:)

data Car = Car String [String] Int [String]

year :: Car -> Int
year (Car _ _ y _) = y

filterByYear :: Int -> [Car] -> [Car]
filterByYear chosenYear cars = filter (\car -> year car == chosenYear) cars

showCar :: Car -> String
showCar car = undefined -- you can implement this how you like

displayCarsByYear :: Int -> IO ()
displayCarsByYear chosenYear = mapM_ (putStrLn . showCar) filteredCars
    where filteredCars = filterByYear chosenYear testDatabase

在这里解释几件事似乎是明智的：

匿名函数：(\car -> year car == chosenYear) 是一个匿名函数。它接受一个参数并将其称为car。然后它确定该车的年份是否等于chosenYear。我没有明确写这个函数的类型签名，但它是Car -> Bool。

过滤：我把这个函数交给filter，这样它就可以查看Cars 的列表。当filter 找到该函数返回True 的汽车时，它会将它们放入结果列表中。 False 结果意味着汽车没有通过过滤器。

函数组合：(putStrLn . showCar)这是一个先执行showCar，然后在showCar的结果上使用putStrLn的函数。

在哪里：您会注意到我的代码末尾的 where 语句。它应该是不言自明的，您可以使用let 或where 语句来定义“局部变量”。就口味而言，我更喜欢 where 而不是 let。

列表解析与过滤器：列表解析可以像过滤器功能一样过滤列表。对于函数f :: a -> Bool 和列表xs :: [a]

filter f xs 与 [x | x <- xs, f x] 相同。出于个人喜好，在这种情况下，我更喜欢拼写 filter，因为这样可以清楚地表明我正在过滤列表。

另见LYAH # Maps and filters

--

进一步推荐：使用记录语法

代替

data Car = Car String [String] Int [String]

为什么不

data Film = Film { name :: String
                 , actors :: [String]
                 , released :: Int
                 , characters :: [String]
                 }

（我真的不知道你最后的字符串列表是什么）

这样，你可以像这样构造一个电影：

lotr :: Film
lotr = Film { name = "Lord of the Rings"
            , actors = ["Elijah Wood", "Ian McKellen", "Orlando Bloom"]
            , released = 2001
            , characters = ["Frodo", "Sam", "Pippin", "Merry"]
            }

而且你自动拥有访问函数

• released :: Film -> Int
• name :: Film -> String
• 等等

另见LYAH # Record syntax

Answer 2

重点是：

[putStrLn(filter ((== chosenYear).y)) |  (w x y z) <- testDatabase]

你还没有理解列表理解。 你想要的是：

[ (Car w x y z) | (Car w x y z) <- testDatabase, y==choosenYear]

大概吧。

有

 mapM (putStrLn . formatCarRow) 

您已经订购了：格式化并打印以下列表中的每个元素。因此，列表推导式中的 putStrLn 是完全荒谬的。

请注意 putStrLn 在某种程度上是用词不当：它实际上不会打印任何东西！它只是构造了一个在 IO monad 中执行时会导致打印的东西。这似乎很难理解，但很快你就会明白了。