Haskell 字符串替换

Question

如何用字符串中的多个字符替换一个字符。 我可以用下面的另一个字符替换一个字符：

  replaceO [] = []
  replaceO (x:xs) =
     if x == '('
     then '\n' : replaceO xs
     else x : replaceO xs

但我想用“\n\t\t”替换'('，而不仅仅是'\n'。

--------- 更新 -------------- 根据下面的答案，我可以把它变成一个接受字符串并返回这样的字符串的函数：

ReplaceFun str :: String -> String
ReplaceFun str = do
    concatMap (\str -> if str == '.' then "foo" else [str])

这不起作用，有人可以指出我的错误吗？我对 Haskell 很陌生。

这是嵌套缩进的内容：

replaceO (x:xs) n l =
    if x == '('
    then "\n" ++ (showTabs n "-") ++ replaceO xs (n + 1) 'l'
    else
        if x == ')'
        then "\n" ++ (showTabs n "-") ++ replaceO xs (n - 1) 'l'
        else x : replaceO xs n 'l'

Answer 1

只需使用concatMap

Prelude> concatMap (\x -> if x == '.' then "foo" else [x]) "example..."
"examplefoofoofoo"

Answer 2

扩展你的例子，你可以用 "\n\t\t" 代替 "(" 只需在递归调用的结果前面加上多个东西

replace1 [] = []
replace1 (x:xs) =
   if x == '('
   then '\n' : '\t' : '\t' : replace1 xs
   else x : replace1 xs

当然，这相当于使用"\n\t\t" ++

replace2 [] = []
replace2 (x:xs) =
   if x == '('
   then "\n\t\t" ++ replace2 xs
   else x : replace2 xs

如果我们注意到x : 等价于[x] ++

replace3 [] = []
replace3 (x:xs) =
   if x == '('
   then "\n\t\t" ++ replace3 xs
   else [x] ++ replace3 xs

然后我们可以分解出重复的递归调用

replace4 [] = []
replace4 (x:xs) = (if x == '(' then "\n\t\t" else [x]) ++ replace4 xs

那么为了清楚起见，我们可以将if 语句过滤成一个函数：

replace5 [] = []
replace5 (x:xs) = f x ++ replace5 xs
  where f x = if x == '(' 
              then "\n\t\t" 
              else [x]

然后我们可以重新组织我们的代码 - 而不是交替地将 f 应用于每个 x 和 将它附加到我们的结果中，我们可以将f 应用于所有xs，然后连接所有结果：

replace6 xs = concat $ map f xs
  where f x = if x == '(' 
              then "\n\t\t" 
              else [x]

但是concat $ map f xs 被频繁使用以至于它有了另一个名字：

replace7 xs = concatMap f xs
  where f x = if x == '(' 
              then "\n\t\t" 
              else [x]

其实它还有一个，因为[]是一个monad：

replace8 xs = xs >>= f
  where f x = if x == '(' 
              then "\n\t\t" 
              else [x]

但如果我们这样做，我们还不如完全使用 Monad：

replace9 xs = do
  x <- xs
  if x == '(' 
     then "\n\t\t" 
     else [x]

但我个人可能只会停在replace7。