Haskell Vector Typeclass：[a] -> [a] -> a 的函数

Question

好的，我正在尝试围绕类型类进行研究，因此我正在尝试为几何矢量运算定义一个类型类。我设法让它在组件方面工作+,-,*,/;，但我在点积上苦苦挣扎。

class GeomVector a where
  (>+) :: a -> a -> a
  (>-) :: a -> a -> a
  (>*) :: a -> a -> a
  (>/) :: a -> a -> a

  (>.) :: a -> a -> Double

data Vector a = Vec [a]
              deriving Show

instance (Fractional a) => GeomVector (Vector a) where
  (>+) (Vec u) (Vec v) = Vec $ zipWith (+) u v
  (>-) (Vec u) (Vec v) = Vec $ zipWith (-) u v
  (>*) (Vec u) (Vec v) = Vec $ zipWith (*) u v
  (>/) (Vec u) (Vec v) = Vec $ zipWith (/) u v

  (>.) (Vec u) (Vec v) = sum $ u >* v

显然我对 (>.) 的实例定义不起作用，因为结果的类型是 Fractional a，而不是 Double。

但我不知道如何从类中的声明中获得这种行为。

我喜欢做的是：

class GeomVector [a] where
  (>.) :: [a] -> [a] -> a

但是这是无效的，因为[a] 是一个类型而不是一个类型变量。

我希望我能更好地解释这一点，但老实说，我的理解还不够。希望代码能让我更清楚我正在努力解决的问题。

Answer 1

这是一个可行的选择：

class GeomVector v where
  (>+) :: Num a=> v a -> v a -> v a
  (>-) :: Num a=> v a -> v a -> v a
  (>*) :: Num a=> v a -> v a -> v a
  (>/) :: Fractional a=> v a -> v a -> v a
  (>.) :: Num a=> v a -> v a -> a

data Vector a = Vec { vecList :: [a] }
              deriving Show

instance GeomVector Vector where
  (>+) (Vec u) (Vec v) = Vec $ zipWith (+) u v
  (>-) (Vec u) (Vec v) = Vec $ zipWith (-) u v
  (>*) (Vec u) (Vec v) = Vec $ zipWith (*) u v
  (>/) (Vec u) (Vec v) = Vec $ zipWith (/) u v

  (>.) u v = sum $ vecList (u >* v)

所以你所有的GeomVector 实例都会有一个类似* -> * 的Monad 类。并且这些方法的类型并没有不必要地限制为 Fractional 类型，因为你在其中的某个地方进行了划分。

您还可以考虑使您的类尽可能小（使>. 成为类外部的多态函数）以及您真正想要的是否是一个类型类。但这一切都取决于你的设计，我不想假设我比你更了解这一点！