Perl 首先将代码编译为中间表示，然后执行它。由于 if 是在运行时评估的，而 use 是在编译期间处理的，因此您不是有条件地导入模块。
要解决此问题，有多种可能的策略：
- 使用
use if pragma 进行条件导入
- 带有 BEGIN 块的条件导入
-
require模块
- 使用
eval 延迟编译
要仅在满足特定条件时导入模块，您可以使用if pragma：
use if $^O eq 'MSWin32', 'Win32';
您还可以在编译期间通过将代码放入 BEGIN 块来运行代码：
BEGIN {
if ($^O eq 'MSWin32') {
require Win32;
Win32->import; # probably not necessary
}
}
BEGIN 块的行为与上面的 use if 完全相同。
请注意，我们必须在这里使用require。使用use Win32，模块将在开始块的编译期间加载，从而绕过if。使用require，模块在开始块的运行时加载，也就是在周围代码的编译期间。
在这两种情况下，Win32 模块只会在 Windows 下导入。这使得 MB_ICONINFORMATION 常量在非 Windows 系统上未定义。在这种代码中，最好不要导入任何符号。取而代之的是，对所有内容使用完全限定名称，并为函数调用使用括号（此处为：Win32::MB_ICONINFORMATION()）。随着这一变化，仅使用 require 而不是 use if 也可以工作。
如果您需要稍后运行代码，您可以使用 string-eval。但是，这可能会导致安全问题，更难以调试，并且通常速度较慢。例如，您可以这样做：
if ($^O eq 'MSWin32') {
eval q{
use Win32;
Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');
1;
} or die $@; # forward any errors
}
- 因为
eval 默认情况下会消除任何错误，所以您必须检查成功并可能重新抛出异常。 1 语句确保经过评估的代码在成功时返回真值。如果发生错误，eval 返回undef。 $@ 变量保存最后一个错误。
-
q{...} 是另一种引用结构。除了大括号作为字符串分隔符之外，它与'...'（单引号）完全相同。
如果你有很多代码只能在某个平台上运行，那么对每个 sn-p 使用上述策略是很乏味的。相反，为每个平台创建一个模块。例如：
本地/MyWindowsStuff.pm：
package Local::MyWindowsStuff;
use strict;
use warnings;
use Win32;
sub show_message {
my ($class, $title, $contents) = @_;
Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');
}
1;
本地/MyPosixStuff.pm：
package Local::MyPosixStuff;
use strict;
use warnings;
sub show_message {
warn "messagebox only supported on Windows";
}
1;
在这里，我将它们编写为可用作类。然后我们可以有条件地加载这些类之一：
sub load_stuff {
if ($^O eq 'MSWin32') {
require Local::MyWindowsStuff;
return 'Local::MyWindowsStuff';
}
require Local::MyPosixStuff;
return 'Local::MyPosixStuff';
}
my $stuff = load_stuff();
最后，我们不是在代码中添加条件，而是在加载的类上调用方法：
$stuff->show_message('Aloha!', 'Win32 Msgox');
如果您不想创建额外的包，一种策略是评估代码参考：
sub _eval_or_throw { my ($code) = @_; return eval "$code; 1" or die $@ }
my $show_message =
($^O eq 'MSWin32') ? _eval_or_throw q{
use Win32;
sub {
Win32::MsgBox("Aloha!", MB_ICONINFORMATION, 'Win32 Msgbox');
}
} : _eval_or_throw q{
sub {
warn "messagebox only supported on Windows";
}
};
然后：$show_message->() 调用此代码。这避免了使用eval 重复编译相同的代码。当然，仅当此代码在每个脚本中运行多次时才重要，例如在循环内或子程序内。