Win10 CMD 只导出目录和子目录中的文件名

Question

我想用Win10 CMD解压成txt文件，只有目录和子目录的文件名。

离我最近的是

V:\Scanned Pictures>dir *.jpg /s/d/a:-d "folderpath" > test1.txt

它只列出文件名，但也包括目录的“标题”，如：

================================================================= Not wanted
 Volume in drive V is Pictures
 Volume Serial Number is C1FA-29F2

 Directory of V:\Scanned Pictures\1988-06 California trip
================================================================= Not Wanted
1988-06 California trip Kathleen Beach 1.jpg   <<<-- Just the file name

Answer 1

只需添加 /b 选项

dir *.jpg /b/s/d/a:-d "folderpath" > test1.txt

根据 dir /? 信息，/b 使 dir 显示无标题或摘要的裸格式

Answer 2

我找到了一个两部分的解决方案。

dir *.jpg /s/b/a-d > test.txt - 生成一个仅列出路径和文件名的文件 将内容复制到 Excel Excel 查找/替换 *\ 为 null - 删除路径

• 我的原始问题中未列出额外步骤 数据文本到列以分隔从文件名中获取的日期

感谢大家的建议和意见，您让我走上了寻找解决方案的道路。

谢谢，注意安全！

Answer 3

有很多选项可以满足您的要求，这里只是其中的一部分：

如果您想要与问题中完全相同的格式，但删除了无文件名行，则只需使用 findstr 删除不需要的行。

您可以通过省略以空格开头的行来做到这一点，（假设您没有以空格字符开头的文件名）：

Dir /S/D/A:-D "folderpath\*.jpg" 2>NUL|%__AppDir__%findstr.exe /VBC:" ">"test1.txt"

如果您想进一步删除空行，请将其通过另一个findstr：

Dir /S/D/A:-D "folderpath\*.jpg" 2>NUL|%__AppDir__%findstr.exe /VBC:" "|%__AppDir__%findstr.exe /V "^$">"test1.txt"

---

如果您不需要宽列排序格式，但仍只需要文件名，那么您可以使用forfiles：

%__AppDir__%forfiles.exe /P "folderpath" /M "*.jpg" /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE Echo @File">"test1.txt"

如果您不希望它们被双引号括起来，那么您可以进一步扩展它来做到这一点：

%__AppDir__%forfiles.exe /P "folderpath" /M "*.jpg" /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE For /F \"Delims=\" %G In (@File)Do Echo %~G">"test1.txt"

虽然forfiles 是一个相对低效的命令，而且你现在使用的是for-loop，但你可以直接使用for-loop：

(For /F "Delims=" %G In ('Dir /B/S/A-D "folderpath\*.jpg" 2^>NUL')Do @Echo %~nxG)>"test1.txt"

如果您想确保仅输出文件扩展名为 .jpg 的文件，（与那些以 .jpg 开头的文件相反，如使用 dir 命令），那么您也可以改用where 命令。

(For /F "Delims=" %G In ('%__AppDir__%where.exe /R "folderpath" *.jpg 2^>NUL')Do @Echo %~nxG)>"test1.txt"

---

[编辑 /]

以下示例已包含在您发布的答案中，这表明 folderpath 不是必需的，因为您正在当前目录中工作。我没有重新复制文字，只是按相同顺序的代码示例：

Dir /S/D/A:-D *.jpg 2>NUL|%__AppDir__%findstr.exe /VBC:" ">"test1.txt"

Dir /S/D/A:-D *.jpg 2>NUL|%__AppDir__%findstr.exe /VBC:" "|%__AppDir__%findstr.exe /V "^$">"test1.txt"

%__AppDir__%forfiles.exe /M *.jpg /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE Echo @File">"test1.txt"

%__AppDir__%forfiles.exe /M *.jpg /S /C "%__AppDir__%cmd.exe /D/Q/C If @IsDir==FALSE For /F \"Delims=\" %G In (@File)Do Echo %~G">"test1.txt"

(For /F "Delims=" %G In ('Dir /B/S/A-D *.jpg 2^>NUL')Do @Echo %~nxG)>"test1.txt"

(For /F "Delims=" %G In ('%__AppDir__%where.exe /R . *.jpg 2^>NUL')Do @Echo %~nxG)>"test1.txt"