从 cmd 获取数据，拆分值并将它们插入到文本框中

Question

我正在尝试从 cmd 读取电池信息。如何提取每个值并将它们放入各自的文本框中，如下图所示？

这是我的代码：

Private Results As String
Private Delegate Sub delUpdate()
Private Finished As New delUpdate(AddressOf UpdateText)

Private Sub UpdateText()
    TextBox11.Text = Results
End Sub

Private Sub batt_Load(sender As Object, e As EventArgs) Handles MyBase.Load
    Dim CMDThread As New Threading.Thread(AddressOf CMDAutomate)
    CMDThread.Start()
End Sub

Private Sub CMDAutomate()
    Dim myprocess As New Process
    Dim StartInfo As New System.Diagnostics.ProcessStartInfo
    StartInfo.FileName = "cmd" 'starts cmd window
    StartInfo.RedirectStandardInput = True
    StartInfo.RedirectStandardOutput = True
    StartInfo.UseShellExecute = False 'required to redirect
    StartInfo.CreateNoWindow = False 'creates no cmd window
    myprocess.StartInfo = StartInfo
    myprocess.Start()
    Dim SR As System.IO.StreamReader = myprocess.StandardOutput
    Dim SW As System.IO.StreamWriter = myprocess.StandardInput
    SW.WriteLine("adb shell dumpsys battery") 'the command you wish to run.....
    SW.WriteLine("exit") 'exits command prompt window
    Results = SR.ReadToEnd 'returns results of the command window
    SW.Close()
    SR.Close()
    'invokes Finished delegate, which updates textbox with the results text
    Invoke(Finished)
End Sub

Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click
    Dim value As String = TextBox11.Text
    Dim topic_start As String = topic_start = value.LastIndexOf("AC Powered:") + 1
    Dim topic As String = value.Substring(topic_start, value.Length - topic_start)
    TextBox1.Text = topic.ToString
End Sub

Button1 在图片中标记为Get Battery Information。

Answer 1

 Private Sub UpdateText()
  Dim xList As New List(Of KeyValuePair(Of String, String))
    Results = Results.Replace(vbLf, "")
    Dim LineSplit() As String = Results.Split(vbCr)
    For Each xLine As String In LineSplit
        If xLine <> "" Then
            xList.Add(New KeyValuePair(Of String, String)(xLine.Split(":")(0), xLine.Split(":")(1).Trim.Replace(" ", "")))
        End If
    Next
'do some work here to put the values in the right textboxes

End Sub

您可以让自己成为一个自定义控件，由您在应用中使用的标签和文本框组成。然后，您只需将列表的每个条目传递给您的自定义控件。使添加或删除字段变得更容易，而无需大量的 IF then 或大的 Select Case

Answer 2

这是一种使用IndexOf()、Substring() 方法和Length 属性从用换行符(Enviroment.NewLine) 分隔的文本中提取值的方法：

Private Sub UpdateGUI()
    Dim lines As String() = TextBox1.Text.Split(New String() {Environment.NewLine}, StringSplitOptions.RemoveEmptyEntries)

    For Each itm In lines
        MsgBox(itm.Substring(itm.IndexOf(":") + 1, itm.Length - itm.IndexOf(":") - 1))
    Next
End Sub

Answer 3

除非您的 TextBoxes 的名称与返回字符串中的值完全相同（无论如何您都必须将空格转换为其他字符），否则除了手动编码每种情况外，实际上没有任何方法可以做到这一点。应该这样做，只需相应地更改文本框的名称：

Private Sub UpdateText()
    Dim lines() As String = Results.Split(vbCrLf.ToCharArray, StringSplitOptions.RemoveEmptyEntries)
    For Each line In lines
        Dim values() As String = line.Split(":")
        Select Case values(0).ToUpper.Trim
            Case "AC POWERED"
                TextBox1.Text = values(1).ToUpper.Trim
            Case "USB POWERED"
                TextBox2.Text = values(1).ToUpper.Trim
            Case "WIRELESS POWERED"
                TextBox3.Text = values(1).ToUpper.Trim
            Case "STATUS"
                TextBox4.Text = values(1).ToUpper.Trim
            Case "HEALTH"
                TextBox5.Text = values(1).ToUpper.Trim
            Case "PRESENT"
                TextBox6.Text = values(1).ToUpper.Trim
            Case "LEVEL"
                TextBox7.Text = values(1).ToUpper.Trim
            Case "SCALE"
                TextBox8.Text = values(1).ToUpper.Trim
            Case "VOLTAGE"
                TextBox9.Text = values(1).ToUpper.Trim
            Case "TEMPERATURE"
                TextBox10.Text = values(1).ToUpper.Trim
            Case "TECHNOLOGY"
                TextBox11.Text = values(1).ToUpper.Trim
            Case Else
                MessageBox.Show(line, "Unknown Value")
        End Select
    Next
End Sub

如果您以可预测的方式命名您的文本框，那么您可以使用Controls.Find() 并将代码缩短为以下内容。例如，将空格更改为下划线，并在前面添加“txt”：“txtAC_Powered”、“txtUSB_Powered”、“txtStatus”、“txtHealth”等。大小写无关紧要，因为无论如何都会找到匹配项。这意味着您在命名控件时需要手动操作，而不是编写冗长的 select case 语句（或其他内容）：

Private Sub UpdateText()
    Dim lines() As String = Results.Split(vbCrLf.ToCharArray, StringSplitOptions.RemoveEmptyEntries)
    For Each line In lines
        Dim values() As String = line.Split(":")
        Dim ctlName As String = "txt" & values(0).Replace(" ", "_").Trim
        Dim ctl As Control = Me.Controls.Find(ctlName, True).FirstOrDefault
        If Not IsNothing(ctl) Then
            ctl.Text = values(1).ToUpper.Trim
        End If
    Next
End Sub