我需要按一个特定的键并让我的脚本“转到”脚本中的另一部分

Question

我有一个急需帮助的批处理脚本。我使用批处理脚本从文件夹中抓取文件并移动它们。该脚本每 30 秒扫描一次文件夹，但您也可以“按一个键继续”。我需要更改它，以便我可以按特定键，不管是什么键，然后让它转到我的脚本的顶部位置进行重置。

以下是我目前拥有的精简版。

@echo off

set /p username=ENTER LOGIN:

echo.

:pc

echo   1 -- Flats
echo   2 -- Simple Tabletop

set /P rmFunc="Enter a choice: "
for %%I in (1 x) do if #%rmFunc%==#%%I goto run%%I

:run1
set pc=300
goto begin

:run2
set pc=400
goto begin

:begin
set studio=TT
set computer=Handbag_1
set setnumber=
set studiosetnumber=%studio%_%setnumber%
set delay_swch=5
set delay_loop=30

:bottom

echo logged in as: %username%

timeout /t %delay_loop%
GOTO BOTTOM

Answer 1

使用 TIMEOUT 时无法确定按下了哪个键，因此该命令无济于事。

您可以使用带有 /T（超时）和 /D（默认）选项的 CHOICE 命令。您不能再简单地按任何键。相反，您只能按一个键重新启动，然后按另一个特定键继续，或者等到返回默认值（继续）。最大的缺点是它不再有视觉倒计时。

echo Press C to Continue, or R to Restart
choice /c cr /d c /t 30 /n /m "The process will automatically continue in 30 seconds "
if errorlevel 2 goto pc
goto bottom

您可以通过添加第三个未记录的默认选项并将超时设置为 1 秒来显示倒计时。如果返回默认值，则它会递减计数器。一旦计数器达到 0，则所需的时间已经过去，您将其视为继续。

我使用 SET /P 技巧来显示不带换行符的提示。我以回车结束，以便从同一行的开头显示下一个提示。

倒计时时间会有点偏，但应该足够好了。

必须定义回车变量，并且必须在靠近顶部（在任何循环标签之前）启用延迟扩展。

:: Define CR to hold a carriage return (0x0D)
for /f %%A in ('copy /Z "%~dpf0" nul') do set "CR=%%A"

:: Delayed expansion must be enabled to use the CR variable
setlocal enableDelayedExpansion

定时器代码就变成了

set wait=15
:waitLoop
<nul set /p ="Press C to Continue, or R to Restart. Auto continue in %wait% seconds.   !CR!"
choice /c 0cr /t 1 /d 0 >nul
if errorlevel 3 echo(&goto pc
if errorlevel 2 echo(&goto bottom
set /a wait-=1
if %wait% equ 0 echo(&goto bottom
goto :waitLoop

Answer 2

timeout 不返回 errorlevel 如果被中断，所以解决这个问题的一种方法可能是时间 timeout

@ECHO Off
SETLOCAL
SET /a "starttime=1%time:~-5,2%%time:~-2%"
timeout /t 30
SET /a "endtime=1%time:~-5,2%%time:~-2%"
IF %endtime% lss %starttime% SET /a endtime +=6000
SET /a elapsed=endtime - starttime
ECHO %elapsed%

GOTO :EOF

elapsed 应该包含以数十毫秒为单位的结果时间。对于“无按键”情况，恰好不太可能是 3000，但也许 if %elapsed% gtr 2980 echo no keypress 就足够了。

请注意，我使用hh:mm:ss.hh 的时间格式，因此如果您的时间格式不同，则需要调整time 子字符串。

由于这里的目标是大约 30 秒的超时，因此只能对秒数进行计算。这些值累积为1ss(.)hh，确保没有前导零，因此set /a 不会尝试进入octal 模式。由于结束时间完全有可能在下一分钟，所以加6000通过加分（6000几十毫秒）来补偿

---

由于似乎有必要构建整个批次，

@echo off

set /p username=ENTER LOGIN:

echo.

:pc

echo   1 -- Flats
echo   2 -- Simple Tabletop

set /P rmFunc="Enter a choice: "

:

for %%I in (1 x) do if #%rmFunc%==#%%I goto run%%I

:run1
set pc=300
goto begin

:run2
set pc=400
goto begin

:begin
set studio=TT
set computer=Handbag_1
set setnumber=
set studiosetnumber=%studio%_%setnumber%
set delay_swch=5
set delay_loop=30

:bottom

echo logged in as: %username%


SET /a "starttime=1%time:~-5,2%%time:~-2%"
timeout /t %delay_loop%
SET /a "endtime=1%time:~-5,2%%time:~-2%"
IF %endtime% lss %starttime% SET /a endtime +=6000
SET /a elapsed=endtime - starttime
if %elapsed% leq 2980 goto ???
GOTO BOTTOM

而且 - 好吧，我不得不离开它。您正在将 studio 和 setnumber 设置为代码中的常量。这些是否与“流程类”有关？如果你想重新输入这些数据，那么你需要上面的??? 是begin - 但你需要set /p 这些值（你没有显示。） 至于文件扫描- 您的代码中没有任何地方显示此文件扫描正在发生。我指出的修改将允许您按任意键来中断 30 秒 bottom 循环并重新输入数据。