Windows CMD/BATCH 保留最新的日期戳文件

Question

我有一些文件要整理并保留最新的文件。 我不能通过修改或创建的文件属性日期来做到这一点，我可以做到这一点。

这是文件的命名约定。 文件ABC_YYYYMMDD.txt

• FileABC_20190201.txt
• FileABC_20190125.txt
• FileABC_20190118.txt
• FileABC_20190111.txt
• FileABC_20190104.txt

您可以看到日期戳在文件名本身中。这些文件每周生成一次。所以我想有一个批处理文件循环遍历它们并删除除最新日期文件之外的所有文件。我真的在寻找如何做到最好，但我没有找到太多，所以我需要一些想法。我更喜欢纯 cmd 解决方案，但我也对 powershell 解决方案持开放态度。

---

我自己尝试的是用...解析出日期

@echo off
setlocal enabledelayedexpansion
for /f "tokens=* delims= " %%G IN ('dir/b /a-d "C:\Users\thomas.maus\Documents\Tom\dev\Test Batch Files\dev\sortbyFileDateName\FileABC_*.txt"') do (

            set fileName=%%G 
            Set theDate=!fileName:~8,8!
            echo !theDate!


)

然后我想以某种方式从循环的结果中获取这些日期并执行类似的操作

if "%theDate%" GEQ "*****not sure what to put here*****" (
    del *all the old files, also not sure what to put here*
)  

Answer 1

这个怎么样？

@echo off
for /f "skip=1" %%i in ('dir /o-n /b *.txt') do del %%i

如果您只想先对其进行测试（看看它会删除什么），请执行以下操作：

@echo off
for /f "skip=1" %%i in ('dir /o-n /b *.txt') do echo %%i

Answer 2

如果您不关心文件日期而只关心文件名中的日期，您可以执行以下操作，因为 FileABC 部分始终相同且不包含任何 _ 本身：

pushd "C:\Users\thomas.maus\Documents\Tom\dev\Test Batch Files\dev\sortbyFileDateName" && (
    for /F "skip=1 delims= eol=|" %%F in ('
        dir /B /A:-D "FileABC_????????.txt" ^
            ^| sort /R
    ') do (
        del "%%F"
    )
    popd
)

虽然sort /R 进行字母排序，但由于您选择了日期格式，这可以确保字母顺序等于字母数字顺序。

Answer 3

我们只是遍历文件，按日期降序排序，然后跳过第一个文件，现在是最新的：

@for /f "skip=1" %%a in ('dir /b /o-d *.txt') do @echo @del %%a

重要！

此示例将仅echo 删除命令作为安全措施，因此您不会删除不应该拥有的文件。要执行实际删除，请从该行中删除 @echo。

要了解有关我们使用的函数的更多信息，请从cmd.exe 运行以下命令

• for /?
• dir /?

Answer 4

作为一个附加选项，以防文件名前缀在整个过程中发生变化并且只有 _YYYYMMDD.txt 保持不变，您仍然可以使用该日期执行任务，因为它已经按字母顺序排序。

这是一个例子：

@Echo Off
Set "SrcDir=%UserProfile%\Documents\Tom\dev\Test Batch Files\dev\sortbyFileDateName"
For /F "Delims==" %%A In ('Set $ 2^>Nul') Do Set "%%A="
Set "_="
For /F Delims^=^ EOL^= %%A In ('Where "%SrcDir%":*_????????.txt 2^>Nul'
) Do Set "_=%%~nA" & Call Set "$%%_:~-8%%=%%A"
If Not Defined _ Exit /B
For /F "Tokens=1* Delims==" %%A In ('Set $ 2^>Nul') Do Set "_=%%B"
For /F Delims^=^ EOL^= %%A In ('Where "%SrcDir%":*_????????.txt^|Find /V "%_%"'
) Do Del /A /F "%%A"

这利用了Set 命令将按字母顺序输出变量的事实。

• 2 到 4 行只是定义和取消定义我们将使用的变量。
• 5 和6 行是单行，为了便于阅读，分成两行。这将使用文件基名的最后八个字符将变量设置为完整文件名的值。
• 包含7 行以退出脚本，以防在2 行设置的目录中找不到基本名称以下划线后跟八个字符结尾的.txt 文件。
• 8 行是这里的特殊行，它按字母顺序输出每个变量和对应的值。输出设置为一个变量，该变量会覆盖自身，直到循环结束。这意味着最新的文件，按字母顺序排列的最后一个，与以最新日期命名的文件的值一起保存。
• 9 和10 行再次将单行拆分为两行以提高可读性。这将再次循环目录中的所有匹配文件，并使用Find 命令排除输出与变量中保存的文件匹配的文件作为具有最新日期的文件。使用Del 命令简单地删除每个文件输出。

请注意，此脚本假定您每个日期只有一个文件，因为您只声明这些文件每周生成一次。