重命名 *.nfo 文件以匹配它们的 *.mkv

Question

尝试组织节目 *.nfo 文件，使它们与匹配的 mkv 同名（编辑：avi woops 不会真正更改代码）。

Test Folder:
76107.2.1.nfo 
76107.2.2.nfo
76107.2.3.nfo
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi

现在 76107.2.*.nfo 中的剧集编号在后面的文件夹中是错误的，测试文件夹中的相似性只是因为它是本季的第一季。所以我不能简单地比较名称以匹配它们，但它们的顺序正确，所以我尝试使用计数器将第一个 *.nfo 重命名为与第一个 *.avi 相同，然后将第二个 *.nfo 重命名为与第二个 *.avi 相同，依此类推！

我制作了一个我认为应该可以工作的脚本，但它什么也没做。任何帮助将非常感激！ 编辑感谢 Aacini，它现在可以工作了，除了在代码中注明的一个奇怪的错误。

@echo on
setlocal enableDelayedExpansion

set cnta=0
Set cntb=0
for %%b in (*.avi) do (
 set /a cnta=cnta+1
 set line_!cnta!=%%~Nb
)

for %%c in (*.nfo) do (
 set /a cntb=cntb+1
 for %%i in (!cntb!) do ren "%%~fc" "!line_%%i!.nfo"
)

错误：第一个 nfo 似乎被撞到了列表的末尾，但它的位置仍然保留。与其他所有 nfo 一样，它的命名与相应的 avi 相匹配。

Test 1 (Original Test Folder) Results:
.nfo
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.nfo
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.nfo

Test 2 (Added Extra Bonus File) Results:
Doctor Who - S02E01 (009) - Planet of Giants (1) - Planet of Giants.avi
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.avi
Doctor Who - S02E01 (009) - Planet of Giants (2) - Dangerous Journey.nfo
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.avi
Doctor Who - S02E01 (009) - Planet of Giants (3) - Crisis.nfo
Doctor Who - S02E01 (009) - Planet of Giants (4) - The Making of Planet of Giants.avi
Doctor Who - S02E01 (009) - Planet of Giants (4) - The Making of Planet of Giants.nfo

某些文件夹将在列表末尾包含没有匹配 nfo 的奖励视频，但它们始终位于末尾。我阅读了 nfo 以验证仅“.nfo”（测试 1）/“Doctor Who - S02E01 (009) - 巨人星球 (4) - 巨人星球的制作.nfo”（测试 2）放错了位置，他们应该被《神秘博士 - S02E01 (009) - 巨人星球(1) - 巨人星球.nfo》

Answer 1

命名line_!cnta! 变量的正确术语是数组。您可以在this post 的批处理文件中查看阵列管理的完整描述。例如，您的代码可能会这样修复：

编辑：修复了小错误

@echo on
setlocal enableDelayedExpansion

set cnta=0
Set cntb=0

for %%b in (*.mkv) do (
 set /a cnta=cnta+1
 set line_!cnta!=%%~Nb
)

for /F "delims=" %%c in ('dir /B *.nfo') do (
 set /a cntb=cntb+1
 for %%i in (!cntb!) do ren "%%~fc" "!line_%%i!.nfo"
)

Answer 2

我认为这对你有用。一旦您认为它看起来正确，您应该将 echo ren 更改为 ren。

@echo on
setlocal enableDelayedExpansion

set cnta=0
set cntb=0

for %%a in (*.mkv) do (
    set /a cnta=cnta+1
    set line_!cnta!=%%a
)

for %%b in (*.nfo) do (
    set /a cntb=cntb+1
    set newname=line_!cntb!
    call set newname=%%!newname!%%
    echo ren "%%~fb" "!newname!"
)

我想你会更喜欢这样的循环。这次我实际上已经全部测试过了：

@echo on
setlocal enableDelayedExpansion

set cnta=0
set cntb=0

for /f "usebackq delims=" %%a in (`dir *.mkv /a-d /b /on`) do (
    set /a cnta=cnta+1
    set line_!cnta!=%%a
)

for /f "usebackq delims=" %%b in (`dir *.nfo /a-d /b /on`) do (
    set /a cntb=cntb+1
    set newname=line_!cntb!
    call set newname=%%!newname!%%
    echo ren "%%~fb" "!newname!"
)

如果您对使用批处理脚本有任何真正的兴趣，那么您需要大量的耐心和反复试验才能真正开始点击。它可能非常错综复杂。

Answer 3

既然您似乎在寻找替代方案，那么每个 .nfo 文件是否都包含其对应的 .mkv 文件的名称？如果是这样，您可以使用find 和条件执行通过.nfo 的内容将.mkv 与其.nfo 配对。这比 shawn 和 Aacini 的答案效率低很多（很多！），但至少您不必担心文件是否按这种方式排列。

@echo off
setlocal

for %%I in (*.mkv) do (
    for %%x in (76107*.nfo) do if not exist "%%~nI.nfo" (
        find /i "%%~nxI" "%%x" >NUL && ren "%%x" "%%~nI.nfo"
    )
)