awk 整体读取文件

Question

让一个文件内容如下-

abcdefghijklmn
pqrstuvwxyzabc
defghijklmnopq

一般来说，如果使用 awk 执行任何操作，它会逐行迭代并在每一行上执行该操作。

例如：

awk '{print substr($0,8,10)}' file

O/P：

hijklmn
wxyzabc
klmnopq

我想知道一种方法，其中文件中的所有内容都被视为单个变量，awk 只打印一个输出。

所需的 O/P 示例：

hijklmnpqr

对于给定的问题，我并不希望得到所需的输出，但总的来说，如果有人能提出一种方法将文件的内容作为一个整体提供给 awk，我将不胜感激。

Answer 1

这是gawk 解决方案

来自docs：

有时您可能希望将整个数据文件视为一条记录。 实现这一点的唯一方法是给 RS 一个您知道不会出现在输入文件中的值。 这很难以一般方式实现，因此程序始终适用于任意输入文件。

---

$ cat file
abcdefghijklmn
pqrstuvwxyzabc
defghijklmnopq

RS 必须设置为存档中不存在的模式，遵循文档中的Denis Shirokov 建议（感谢@EdMorton）：

$ gawk '{print ">>>"$0"<<<<"}' RS='^$' file
>>>abcdefghijklmn
pqrstuvwxyzabc
defghijklmnopq

abcdefghijklmn
pqrstuvwxyzabc
defghijklmnopq
<<<<

技巧是粗体：

它通过将 RS 设置为 ^$ 来工作，这是一个永远不会出现的正则表达式 如果文件有内容则匹配。 gawk 将文件中的数据读入 tmp，试图匹配 RS。 每次读取后匹配都会失败，但很快就会失败，因此 gawk 会用文件的全部内容填充 tmp

---

所以：

$ gawk '{gsub(/\n/,"");print substr($0,8,10)}' RS='^$' file

返回：

hijklmnpqr

Answer 2

使用 GNU awk 进行多字符 RS（最佳方法）：

$ awk -v RS='^$' '{print substr($0,8,10)}' file
hijklmn
pq

如果您的输入不能包含 NUL 字符，则使用其他 awk：

$ awk -v RS='\0' '{print substr($0,8,10)}' file
hijklmn
pq

与其他 awk 不同：

$ awk '{rec = rec $0 ORS} END{print substr(rec,8,10)}' file
hijklmn
pq

请注意，这些都不会产生您想要的输出：

hijklmnpqr

因为他们会按照您说的做（换行符只是输入文件中的另一个字符，没什么特别的）：

"read file as a whole"

要获得您想要的输出，首先需要从文件中删除所有换行符。您可以使用gsub(/\n/,"") 或其他各种方法来做到这一点，例如：

$ awk '{rec = rec $0} END{print substr(rec,8,10)}' file
hijklmnpqr

如果那是真的你想要的。